How can I plot this figure?

Question

I have the formula, the renyi entropy $\frac{1}{1-q}ln(\sum_{i=1}^Np_i^q)$, and the figure I haven't seen before, is it the ContourPlot for N=3 (the condition is $0\le p_1\le1,0\le p_2\le1,p_1+p_2+p_3=1$)?

I only get this:

q = 2;
S1 = 1/(1 - q) Log[p1^q + p2^q + (1 - p2 - p1)^q];
ContourPlot[S1, {p1, 0, 1}, {p2, 0, 1}]

Answer 1

We need to use ternary coordinate,that is we need to mapping the set

{p1,p2,p3}, p1+p2+p3==1,p1>0,p2>0,p3>0

to {x,y} coordinate.

Clear[q, f, ternary, inverseternary, reg, inversereg];
q = 2;
f[{p1_, p2_, p3_}] = 1/(1 - q) Log[p1^q + p2^q + p3^q];
ternary[{p1_, p2_, p3_}] = {p1 + 1/2 p2, Sqrt[3]/2 p2};
inverseternary[{x_, y_}] = {p1, p2, p3} /. 
   Solve[{x == p2 + 1/2 p3, y == Sqrt[3]/2 p3, 
      p1 + p2 + p3 == 1}, {p1, p2, p3}][[1]];
reg = ImplicitRegion[{p1 > 0, p2 > 0, p3 > 0, p1 + p2 + p3 == 1}, {p1,
     p2, p3}];
inversereg = TransformedRegion[reg, ternary];
ContourPlot[f[inverseternary[{x, y}]], {x, 0, 1}, {y, 0, 1}, 
 RegionFunction -> Function[{x, y}, {x, y} ∈ inversereg], 
 Contours -> 20, PlotLegends -> Automatic]