3
$\begingroup$

Let $\varepsilon$ be a complex number of small magnitude and let $1+\varepsilon$ have magnitude $r$ and argument $\theta$. I want to generate the following image in Mathematica:enter image description here

and then I want to see what happens to the image as I change the magnitude of $\varepsilon$ with a slider. In particular, I want to see how the origin-centered circular arc connecting $1+\varepsilon$ to the point $r$ on the real axis approaches the perpendicular from $1+\varepsilon$ to the real axis as the magnitude of $\varepsilon$ approaches $0$. What would be a good way to do this?

This is what I came up with so far:

e := 
  Manipulate[
    FromPolarCoordinates[{mag, Pi/6}], {mag, 0, 1}]; 
    eps := {1, 0} + {e[[0]], e[[1]]}; 
    Graphics[Line[{{0, 0}, {1, 0}, {1, 0} + eps}]
  ]
$\endgroup$
2
  • $\begingroup$ I'm new to mathematica so I haven't gotten very far. I tried using the Graphics and Line functions to plot the vectors, but I couldn't get it to work. $\endgroup$
    – user236343
    Commented Aug 11, 2022 at 12:14
  • $\begingroup$ Ok, it's pretty terrible, but this is what I came up with: e := Manipulate[FromPolarCoordinates[{mag, Pi/6}], {mag, 0, 1}]; eps := {1, 0} + {e[[0]], e[[1]]}; Graphics[Line[{{0, 0}, {1, 0}, {1, 0} + eps}]] $\endgroup$
    – user236343
    Commented Aug 11, 2022 at 12:18

2 Answers 2

2
$\begingroup$

What you are trying to achieve seems functionally equivalent to showing graphically that $\lim_{\theta\to 0}\frac{\sin \theta}{\theta}=1$. Here is an example to achieve that:

Manipulate[
  Graphics[{
     {Thick, Blue, Arrow[{{0, 0}, {1, 0}}]},
     {Red, Arrow[{{0, 0}, {Cos[theta], Sin[theta]}}]},
     {Black, Dashed, Line[{{Cos[theta], Sin[theta]}, {Cos[theta], 0}}]},
     {Black, Circle[{0, 0}, 1, {0, theta}]}
    },
    Axes -> True, PlotRange -> {0, 1.1}
  ],
  {theta, Pi/2, 0}
]

Manipulate output similar to required plot

$\endgroup$
2
$\begingroup$

I do not know if I understood you right. Can modify as needed.

enter image description here

Manipulate[
 Module[{x = 1 + realEps, y = imEps, r},
  r = Sqrt[x^2 + y^2];
  Grid[{{Row[{"r =", r}]},
    {Graphics[{
       {Red, Arrow[{{0, 0}, {x, y}}]},
       {Dashed, Circle[{0, 0}, r, {0, ArcTan[x, y]}]},
       {Text[
         Style[Row[{ArcTan[x, y]*180/Pi , " deg"}], Small], {.7, 0.2}]}
       }, Axes -> True, PlotRange -> {{0, 4}, {0, 3}}, 
      GridLines -> Automatic, GridLinesStyle -> LightGray, 
      ImageSize -> 300
      ]}
    }]
  ]
 ,
 {{realEps, .5, "real part \[Epsilon]"}, 0, 2, .01, 
  Appearance -> "Labeled"},
 {{imEps, 1, "imaginary part \[Epsilon]"}, 0, 3, .01, 
  Appearance -> "Labeled"},
 TrackedSymbols :> {realEps, imEps}
 ]
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.