8
$\begingroup$

For the given matrix

mat = MatrixForm[{{2*g*a*e, 0, 2*g*a*d, 0, -2*g*a*e, 0, 
 g*(-2*c*d - (b*e)/E^(I*f) - E^(I*f)*b*e), 
 g*((I*b*e)/E^(I*f) - I*E^(I*f)*b*e), 
 g*((-E^((-I)*f))*b*d - E^(I*f)*b*d + 2*c*e)}, 
{0, -2*g*a*e, 0, -2*g*a*e, 0, -2*g*a*d, 
 g*((I*b*e)/E^(I*f) - I*E^(I*f)*b*e), 
 g*(-2*c*d + (b*e)/E^(I*f) + E^(I*f)*b*e), 
 g*((I*b*d)/E^(I*f) - I*E^(I*f)*b*d)}, 
{2*g*a*c, 0, g*((a*b)/E^(I*f) + E^(I*f)*a*b), 0, -2*g*a*c, 
 g*((I*a*b)/E^(I*f) - I*E^(I*f)*a*b), 
 g*((-E^((-I)*f))*b*c - E^(I*f)*b*c + 2*d*e), 
 g*((I*b*c)/E^(I*f) - I*E^(I*f)*b*c), g*(a^2 - b^2 + c^2 + d^2 - e^2)}}]

simplifying the singular values treats the products like a*b, b*c etc as complex even when they are defined as real. How to sort this issue?

 T1[a_, b_, c_, d_, e_, f_, g_] = Simplify[SingularValueList[mat][[1]][[1]], 
   Assumptions -> Element[a, Reals] && Element[b, Reals] && 
     Element[c, Reals] && Element[d, Reals] && Element[e, Reals] && 
     Element[a*b, Reals] && Element[a*c, Reals] && Element[a*d, Reals] && 
     Element[a*e, Reals] && Element[b*c, Reals] && Element[b*d, Reals] && 
     Element[b*e, Reals] && Element[c*d, Reals] && Element[c*e, Reals] && 
     Element[d*e, Reals] && 0 < f < Pi && 0 < g < 1]

Which gives for T1[a, b, c, d, 0, \[Pi]/2, g] the following:

 Root[-16*a^8*d^4*g^6 + 16*a^4*b^4*d^4*g^6 - 192*a^6*c^2*d^4*g^6 + 
    32*a^2*b^4*c^2*d^4*g^6 - 352*a^4*c^4*d^4*g^6 + 16*b^4*c^4*d^4*g^6 - 
    192*a^2*c^6*d^4*g^6 - 16*c^8*d^4*g^6 - 32*a^6*d^6*g^6 - 
    96*a^4*c^2*d^6*g^6 - 96*a^2*c^4*d^6*g^6 - 32*c^6*d^6*g^6 - 
    16*a^4*d^8*g^6 - 32*a^2*c^2*d^8*g^6 - 16*c^4*d^8*g^6 - 
    128*a^4*b*c^2*d^3*g^6*Conjugate[b*d] - 128*a^2*b*c^4*d^3*g^6*
     Conjugate[b*d] - 32*a^5*d^3*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    32*a^3*b^2*d^3*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    64*a^3*c^2*d^3*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    32*a*b^2*c^2*d^3*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    32*a*c^4*d^3*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    32*a^3*d^5*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    32*a*c^2*d^5*g^6*Conjugate[a*b]*Conjugate[b*d] - 
    32*a^4*c*d^3*g^6*Conjugate[b*c]*Conjugate[b*d] - 
    32*a^2*b^2*c*d^3*g^6*Conjugate[b*c]*Conjugate[b*d] - 
    64*a^2*c^3*d^3*g^6*Conjugate[b*c]*Conjugate[b*d] - 
    32*b^2*c^3*d^3*g^6*Conjugate[b*c]*Conjugate[b*d] - 
    32*c^5*d^3*g^6*Conjugate[b*c]*Conjugate[b*d] - 
    32*a^2*c*d^5*g^6*Conjugate[b*c]*Conjugate[b*d] - 
    32*c^3*d^5*g^6*Conjugate[b*c]*Conjugate[b*d] + 
    (8*a^6*d^2*g^4 - 8*a^4*b^2*d^2*g^4 + 88*a^4*c^2*d^2*g^4 - 
      16*a^2*b^2*c^2*d^2*g^4 + 88*a^2*c^4*d^2*g^4 - 8*b^2*c^4*d^2*g^4 + 
      8*c^6*d^2*g^4 + 32*a^4*d^4*g^4 - 8*a^2*b^2*d^4*g^4 + 
      64*a^2*c^2*d^4*g^4 - 8*b^2*c^2*d^4*g^4 + 32*c^4*d^4*g^4 + 
      8*a^2*d^6*g^4 + 8*c^2*d^6*g^4 + 16*a^3*b*d^2*g^4*Conjugate[a*b] + 
      16*a*b*c^2*d^2*g^4*Conjugate[a*b] + 16*a^2*b*c*d^2*g^4*
       Conjugate[b*c] + 16*b*c^3*d^2*g^4*Conjugate[b*c] + 
      32*a^2*b*c^2*d*g^4*Conjugate[b*d] + 16*a^2*b*d^3*g^4*Conjugate[b*d] + 
      16*b*c^2*d^3*g^4*Conjugate[b*d] + 8*a^3*d*g^4*Conjugate[a*b]*
       Conjugate[b*d] + 8*a*b^2*d*g^4*Conjugate[a*b]*Conjugate[b*d] + 
      8*a*c^2*d*g^4*Conjugate[a*b]*Conjugate[b*d] + 
      8*a*d^3*g^4*Conjugate[a*b]*Conjugate[b*d] + 
      8*a^2*c*d*g^4*Conjugate[b*c]*Conjugate[b*d] + 
      8*b^2*c*d*g^4*Conjugate[b*c]*Conjugate[b*d] + 
      8*c^3*d*g^4*Conjugate[b*c]*Conjugate[b*d] + 
      8*c*d^3*g^4*Conjugate[b*c]*Conjugate[b*d])*#1 + 
    ((-a^4)*g^2 + 2*a^2*b^2*g^2 - b^4*g^2 - 10*a^2*c^2*g^2 + 
      2*b^2*c^2*g^2 - c^4*g^2 - 10*a^2*d^2*g^2 + 2*b^2*d^2*g^2 - 
      10*c^2*d^2*g^2 - d^4*g^2 - 4*a*b*g^2*Conjugate[a*b] - 
      4*b*c*g^2*Conjugate[b*c] - 4*b*d*g^2*Conjugate[b*d])*#1^2 + #1^3 & , 
  1]
Improve this question
$\endgroup$

1 Answer 1

Reset to default
10
$\begingroup$

You are probably not using Mathematica correctly. First, you shouldn't put MatrixForm into SingularValueList. Second, the way you defined your matrix and function T1 does not work for properly applying the parameters. Lastly, use ComplexExpand to simplify the expression, assuming all variables are real, or Simplify/Refine.

Clear[T1, mat];

mat[a_, b_, c_, d_, e_, f_, 
  g_] := {{2*g*a*e, 0, 2*g*a*d, 0, -2*g*a*e, 0, 
   g*(-2*c*d - (b*e)/E^(I*f) - E^(I*f)*b*e), 
   g*((I*b*e)/E^(I*f) - I*E^(I*f)*b*e), 
   g*((-E^((-I)*f))*b*d - E^(I*f)*b*d + 2*c*e)}, {0, -2*g*a*e, 
   0, -2*g*a*e, 0, -2*g*a*d, g*((I*b*e)/E^(I*f) - I*E^(I*f)*b*e), 
   g*(-2*c*d + (b*e)/E^(I*f) + E^(I*f)*b*e), 
   g*((I*b*d)/E^(I*f) - I*E^(I*f)*b*d)}, {2*g*a*c, 0, 
   g*((a*b)/E^(I*f) + E^(I*f)*a*b), 0, -2*g*a*c, 
   g*((I*a*b)/E^(I*f) - I*E^(I*f)*a*b), 
   g*((-E^((-I)*f))*b*c - E^(I*f)*b*c + 2*d*e), 
   g*((I*b*c)/E^(I*f) - I*E^(I*f)*b*c), 
   g*(a^2 - b^2 + c^2 + d^2 - e^2)}};

T1[a_, b_, c_, d_, e_, f_, g_] := 
 First@SingularValueList[mat[a, b, c, d, e, f, g]]

T1[a, b, c, d, 0, \[Pi]/2, g]
(* Sqrt[4 a d g Conjugate[a d g] + 4 c d g Conjugate[c d g]] *)

Refine[%, {a, b, c, d, e, f, g} \[Element] Reals]
(* Sqrt[4 a^2 d^2 g^2 + 4 c^2 d^2 g^2] *)

Simplify[%, Assumptions -> {a, b, c, d, e, f, g} \[Element] Reals]
(* 2 Sqrt[a^2 + c^2] Abs[d] Abs[g] *)
Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.