3
$\begingroup$

The following is based on this question which shows mathematically that if

$$a = \sqrt[3]{1 + \sqrt{\frac{152}{27}}}- \sqrt[3]{-1 + \sqrt{\frac{152}{27}}}$$

then

$$a^3 + 5 a$$

is an integer.

In Mathematica, though, the result does not hold:

a = Power[1 + Sqrt[152/27], (3)^-1] - Power[-1 + Sqrt[152/27], (3)^-1];

IntegerQ[a^3 + 5 a]

(* False *)

How can we "prove" or compute the proper result?

$\endgroup$
4
  • 7
    $\begingroup$ Using IntegerQ[FullSimplify[a^3+5*a]] gives True. Relevant quote from the documentation: "IntegerQ[expr] returns False unless expr is manifestly an integer (i.e. has head Integer)". In the "Possible Issues" section of the documentation, this kind of problem is discussed for GoldenRatio - 1/GoldenRatio. $\endgroup$
    – user293787
    Aug 3, 2022 at 23:00
  • $\begingroup$ Thanks. That does it! $\endgroup$ Aug 3, 2022 at 23:05
  • 6
    $\begingroup$ I vastly prefer using AlgebraicNumber[] for these sorts of things: IntegerQ[AlgebraicNumber[Power[1 + Sqrt[152/27], 1/3] - Power[-1 + Sqrt[152/27], 1/3], CoefficientList[a^3 + 5 a, a]]]. $\endgroup$ Aug 3, 2022 at 23:06
  • 2
    $\begingroup$ A bit disappointing that ResourceFunction["RadicalDenest"][a^3 + 5*a] splats. $\endgroup$ Aug 3, 2022 at 23:27

2 Answers 2

7
$\begingroup$

A couple more ways:

ToNumberField[a^3 + 5a] ∈ Integers
True
AlgebraicIntegerQ[a^3 + 5a] && Exponent[MinimalPolynomial[a^3 + 5a, x], x] == 1
True
$\endgroup$
1
  • $\begingroup$ Thanks. Your first solution is particularly valuable. ($+1$) $\endgroup$ Aug 4, 2022 at 20:57
5
$\begingroup$
Clear["Global`*"]

a = (1 + Sqrt[152/27])^(1/3) - (-1 + Sqrt[152/27])^(1/3);

Use RootReduce

a^3 + 5 a // RootReduce

(* 2 *)

Or FullSimplify

a^3 + 5 a // FullSimplify

(* 2 *)
$\endgroup$
1
  • 2
    $\begingroup$ Yep... and then perform IntegerQ... $\endgroup$ Aug 3, 2022 at 23:48

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.