1
$\begingroup$

I have tried to get solution of the following ODE:

y''[x]*y'[InverseFunction[y][x]] - y'[x] == 0

Using the code given below, the solution is a formal power series around 0 satisfying y[0] == 0, I want to get the coefficient list of this formal power series which are:{0, 1, 1/2, 0, 1/24, -1/20, 13/180, -197/1680, 2101/10080, -48203/120960, 2938057/3628800, -23059441/13305600, 74408941/19160064, -9409883317/1037836800}.

I ran the code below, but I got only the form of the series but for coefficients list I didn't get the expected result. Thank you for any help.

**Code**
ode = y''[x]*y'[InverseFunction[y][x]] - y'[x] == 0;
initconds = {y[0] == 0};
odeOperator = 
  D[#, {x, 2}]*D[#, x][ InverseFunction[y][x]] - D[#, x] &;
yy = Series[y[x], {x, 0, 10}];
$\endgroup$

1 Answer 1

5
$\begingroup$

The right way to do this is to start with an ansatz (note that the OP has neglected to explicitly declare the y'[0] == 1 condition):

n = 12;
ansatz = x + Sum[C[k] x^k, {k, 2, n}] + O[x]^(n + 1)

and then use InverseSeries[] for inversion, and ComposeSeries[] for composition, before using SolveAlways[] to get the needed coefficients:

ansatz /. First[SolveAlways[D[ansatz, {x, 2}]
                            ComposeSeries[D[ansatz, x], InverseSeries[ansatz]] -
                            D[ansatz, x] == 0, x]]
   x + x^2/2 + x^4/24 - x^5/20 + (13 x^6)/180 - (197 x^7)/1680 +
   (2101 x^8)/10080 - (48203 x^9)/120960 + (2938057 x^10)/3628800 -
   (23059441 x^11)/13305600 + (74408941 x^12)/19160064 + O[x]^13
$\endgroup$
2
  • 1
    $\begingroup$ Interesting type of DE. Thanks for solution. Looks like could have used y'[0]=a and then sub a x+c2 x^2+... $\endgroup$
    – josh
    Commented Jul 24, 2022 at 23:38
  • $\begingroup$ Indeed, that would yield the generic solution, but the coefficient set supplied/expected by the OP implicitly defined that free parameter. ;) $\endgroup$ Commented Jul 25, 2022 at 0:03

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.