How to generate input cells whose code is determined dynamically?

Question

Following this post, I want to use code to generate an input cell with new code. However, unlike the linked post, I want my code to dynamically determine the new code to be printed in the input cell.

The use of Defer is making this difficult. For example, the following works:

makeImportCell[filename_] := 
   CellPrint[ExpressionCell[
       Defer[data = Import[filename]], "Input"]]

makeImportCell["myData.txt"]

Output (as an input cell):

data = Import["myData.txt"]

But if I want the function to manipulate the string filename, it breaks:

makeImportCell[filename_] := Module[{file},
  file = filename <> ".txt"; 
  CellPrint[ExpressionCell[Defer[data = Import[file]], "Input"]]]

makeImportCell["myData"]

Output (as an input cell):

data = Import[file$45844993]

I'd also like to use If statements based on some other variables to alter the code that gets generated, but if I put any Ifs into Defer, they'll be left unevaluated. Maybe the best solution would be to have the function construct a large string containing exactly the code I want to print, and then print this string as input code rather than a string. But I can't figure out how to do this.

---

I just realized I could use

makeImportCell[filename_] := 
   CellPrint[ExpressionCell[
       Defer[data = Import[filename <> ".txt"]], "Input"]]

to accomplish the same thing the second function is trying to do. But this doesn't generalize. I want to be able to manipulate the code (and strings within the code) that is to be generated, inside the body of Module, and then CellPrint exactly the code I want.

---

EDIT

J.M.'s answer prompted me to ask a more general version of this question, and the answer given there is particularly simple and elegant. It solves the problem of converting any arbitrary string of code into an input cell.

Answer 1

You should just use With instead of Module, as Carl Woll suggests in the comments:

makeImportCell[filename_] := With[{file = filename <> ".txt"},
  CellPrint[ExpressionCell[Defer[data = Import[file]], "Input"]]]

However, be aware that usage of CellPrint for producing "Input" cells is discouraged:

I'm not a huge fan of this because of the combination of CellPrint and the "Input" style. This creates Input cells which have GeneratedCell->True and CellAutoOverwrite->True (this is documented behavior of CellPrint). If you start using these cells for real, then you may have unpleasant side effects...like your Input cells disappearing when you evaluate inputs above them. If you really want Input cells, I'd recommend a NotebookWrite based solution. The equivalent formulation would be NotebookWrite[EvaluationNotebook[],Cell[BoxData[ToString[#, InputForm]], "Input"]] &. – John Fultz (Jul 9, 2017 at 5:19)

To generate "Input" cells that behave exactly like regular user-created cells, use NotebookWrite instead:

makeImportCell[filename_] := With[{file = filename <> ".txt"},
  NotebookWrite[EvaluationNotebook[], 
   Cell[BoxData@MakeBoxes[data = Import[file]], "Input"]]]

Further reading:

• Output of code generated by CellPrint goes to the end of notebook

Answer 2

This required a bit more trickery than I would like:

makeImportCell[filename_] := Module[{file},
    file = filename <> ".txt";
    CellPrint[Cell[BoxData[RowBox[{"data", "=", 
                                   RowBox[{"Import", "[",
                                           "\"" <> file <> "\"", "]"}]}]], 
                   "Input"]]]

and then evaluating makeImportCell["fooba"] does print a cell with data = Import["fooba.txt"].