How to get to ComponentMeasurements[] from orthographic projection of a Graphics3D[] object?

Question

Let's say I have some composite 3D graphics of various shapes. For simplicity, let's say these are just two capsules, like below:

myShapes = {CapsuleShape[{{-0.002997, 0., 0.}, {0.002997, 0., 0.}}, 2.997], 
 CapsuleShape[{{5.22693, 0.954974, 0.945536}, {5.23274, 0.956034, 
    0.946586}}, 2.997]}

Graphics3D[myShapes, ViewPoint -> Front, 
 ViewProjection -> "Orthographic"]

Now, from that orthographic projection, I'd like to get a binary image of the "foreground" pixels visible from the projection, so that I can get 2D ComponentMeasurements[] (like area, circularity, etc.)

We can use Jen's function from this answer to get a black "shadow", which seems promising, but such shadow is still a Graphics3D[] object, so it does not seem very useful (but it's cool!):

How could I go about this?

Thanks!

Note: Ideally, the projection should respect the dimensions of the original graphics (say, the diameter/shape of the capsules), but I'm assuming the orthographic projection would take care of that(?)

Answer 1

Edit

If we only need to image,we can use

Clear[plot, img]; 
myShapes = {CapsuleShape[{{-0.002997, 0., 
     0.}, {0.002997, 0., 0.}}, 2.997], 
  CapsuleShape[{{5.22693, 0.954974, 0.945536}, {5.23274, 0.956034, 
     0.946586}}, 2.997]}; 
plot = 
 Graphics3D[{Black, myShapes}, ViewProjection -> "Orthographic", 
  ViewPoint -> {0, -1, 0}, Boxed -> False, PlotRangePadding -> 0, 
  PlotRange -> Full];
 img = ImportString[ExportString[plot, "PNG"]]

Original

• CapsuleShape is the BSplineSurface. It it not easy to handle.

Needs["OpenCascadeLink`"];
Needs["NDSolve`FEM`"];
myShapes = {CapsuleShape[{{-0.002997, 0., 0.}, {0.002997, 0., 0.}}, 
    2.997], CapsuleShape[{{5.22693, 0.954974, 0.945536}, {5.23274, 
      0.956034, 0.946586}}, 2.997]};
shape1 = OpenCascadeShape[myShapes[[1]]];
shape2 = OpenCascadeShape[myShapes[[2]]];
mesh1 = OpenCascadeShapeSurfaceMeshToBoundaryMesh[shape1, 
   "ShapeSurfaceMeshOptions" -> {"AngularDeflection" -> 0.05}];
mesh2 = OpenCascadeShapeSurfaceMeshToBoundaryMesh[shape2, 
   "ShapeSurfaceMeshOptions" -> {"AngularDeflection" -> 0.05}];
mg1 = TransformedRegion[MeshRegion[mesh1], 
    ScalingTransform[0, {0, 1, 0}]] // Quiet;
mg2 = TransformedRegion[MeshRegion[mesh2], 
    ScalingTransform[0, {0, 1, 0}]] // Quiet;
mg = RegionUnion[mg1, mg2];
dist = RegionDistance[mg];
projection = 
 ImplicitRegion[dist@{x, 0, z} <= .02, {x, z}] // DiscretizeRegion
projection // Area

55.6183

• Compare with the 3D graphics.

myShapes = {CapsuleShape[{{-0.002997, 0., 0.}, {0.002997, 0., 0.}}, 
   2.997], CapsuleShape[{{5.22693, 0.954974, 0.945536}, {5.23274, 
     0.956034, 0.946586}}, 2.997]}; 
Graphics3D[
 GeometricTransformation[myShapes, ScalingTransform[0, {0, 1, 0}]]]