6
$\begingroup$

This is an image, each set of data has a face fill

enter image description here

So now I have a set of data, and I've drawn part of it using ListLinePlot3D

data1 = {{2.1, 2.9, 2.8, 1.9, 1.1, 1.2, 2.1}, {2.2, 2.7, 1.1, 2.2, 
    2.7, 1.1, 2.2}, {2.3, 1.7, 2.3, 1.7, 2.3, 1.7, 2.3}, {2.4, 1.0, 
    2.6, 2.4, 1.0, 2.6, 2.4}};
data2 = {{2.1, 2.9, 2.8, 1.9, 1.1, 1.2, 2.1}, {2.2, 2.7, 1.1, 2.2, 
     2.7, 1.1, 2.2}, {2.3, 1.7, 2.3, 1.7, 2.3, 1.7, 2.3}, {2.4, 1.0, 
     2.6, 2.4, 1.0, 2.6, 2.4}} + RandomReal[];

listPlt1 = ListLinePlot3D[data1,
   PlotMarkers -> {Automatic, Medium},
   PlotStyle -> {Directive[Blue], Directive[Green], Directive[Purple],
      Directive[Black]}
   ];
listPlt2 = ListLinePlot3D[data2,
   PlotMarkers -> {Automatic, Medium}
   ];

Show[listPlt1, listPlt2,
 PlotRange -> All]

enter image description here

I try to use the Filling function,But I found it impossible to achieve this effect

Here is a diagram I drew in PowerPoint

How do I achieve this effect in Wolfram

enter image description here

$\endgroup$

2 Answers 2

7
$\begingroup$

Manually draw planes where you need them:

Show[
  listPlt1, listPlt2,
  Graphics3D[{
    Opacity[0.3],
    MapThread[
      {#1, InfinitePlane[{{0, #2, 0},{0, #2, 10},{10, #2, 10}}]}&,
      {{Red, Blue, Green, Black}, Range[4]}
    ]
  }], AxesLabel -> {x, y, z},
  PlotRange -> All
]

same plot as OP, but with four semi transparent planes

$\endgroup$
7
$\begingroup$

An alternative way to draw the desired planes:

Show[listPlt1, listPlt2,
 Graphics3D @
  MapIndexed[{EdgeForm[], Opacity[.2], #, Hyperplane[{0, 1, 0}, #2[[1]]]} &] @
   {Blue, Green, Purple, Black},
 PlotRange -> All]

enter image description here

$\endgroup$
1
  • $\begingroup$ I learn too much! $\endgroup$ Jul 14, 2022 at 12:09

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge that you have read and understand our privacy policy and code of conduct.

Not the answer you're looking for? Browse other questions tagged or ask your own question.