1
$\begingroup$

Consider:

Expre78 = ( b βa (μ (-1 + ν) - ξ) + μ (μ + ξ + ρ) (γa + μ + σ))/(μ (μ + ξ + ρ) σ);

Assuming[
   {b > 0, βa > 0, μ > 0, 0 < ν < 1, βi > 0, ξ > 0, ρ > 0, γa > 0, σ > 0}, 
   Reduce[$Assumptions \[Implies] Expre78 >= 0, {}, Reals]
]

Is this expression positive or negative given the assumptions?

Edit:

if r0<1 then i want to check whether Expre78 <0

r0=(b (\[Mu] - \[Mu] \[Nu] + \[Xi]) (\[Beta]a (\[Alpha] + \[Gamma]i + \
    \[Eta] + \[Mu]) + \[Beta]i \[Sigma]))/(\[Mu] (\[Alpha] + \[Gamma]i + \
    \[Eta] + \[Mu]) (\[Mu] + \[Xi] + \[Rho]) (\[Gamma]a + \[Mu] + \
    \[Sigma]));

        Expre78 = (b \[Beta]a (\[Mu] (-1 + \[Nu]) - \[Xi]) + \[Mu] (\[Mu] + \
\[Xi] + \[Rho]) (\[Gamma]a + \[Mu] + \[Sigma]))/(\[Mu] (\[Mu] + \[Xi] \
+ \[Rho]) \[Sigma]);

Assuming[{b > 0, \[Beta]a > 0, \[Beta]i > 0, \[Mu] > 0, 
  0 < \[Nu] < 1, \[Gamma]a > 0, \[Gamma]i > 0, \[Xi] > 0, \[Rho] > 
   0, \[Eta] > 0, \[Alpha] > 0, \[Sigma] > 0, r0 < 1}, 
 Reduce[$Assumptions \[Implies] Expre78 <= 0, {}, Reals]]
$\endgroup$
2
  • $\begingroup$ Did you try FindInstance[{Expre78 < 0 && b > 0 && \[Beta]a > 0 && \[Mu] > 0 && 0 < \[Nu] < 1 && \[Xi] > 0, \[Rho] > 0, \[Gamma]a > 0, \[Sigma] > 0}, {b, \[Beta]a, \[Mu], \[Nu], \[Xi], \[Rho], \[Gamma]a, \ \[Sigma]}]? $\endgroup$
    – user64494
    Jul 12, 2022 at 14:21
  • $\begingroup$ @user293787 I amended the assumptions $\endgroup$
    – Math
    Jul 12, 2022 at 15:37

1 Answer 1

4
$\begingroup$
Clear["Global`*"]

Expre78 = (b βa (μ (-1 + ν) - ξ) + μ (μ + ξ + ρ) (γa + μ + σ))/
   (μ (μ + ξ + ρ) σ);

It can be either.

To be nonnegative

Assuming[{b > 0, βa > 0, μ > 0, 
  0 < ν <= 1, ξ > 0, ρ > 0, γa > 0, σ > 0}, 
 Reduce[Expre78 >= 0] // Simplify]

(* b βa (μ - μ ν + ξ) <= μ (μ + ξ + ρ) (\
γa + μ + σ) *)

vars = Variables[Level[Expre78, {-1}]];

Nonnegative values

Expre78 >= 0 /. 
 FindInstance[{Expre78 >= 0, b > 0, βa > 0, μ > 0, 
   0 < ν <= 1, ξ > 0, ρ > 0, γa > 0, σ > 0}, vars, 5]

(* {True, True, True, True, True} *)

Negative values

Expre78 < 0 /. 
 FindInstance[{Expre78 < 0, b > 0, βa > 0, μ > 0, 
   0 < ν <= 1, ξ > 0, ρ > 0, γa > 0, σ > 0}, vars, 5]

(* {True, True, True, True, True} *)

EDIT: For the revised question

Clear["Global`*"]

r0 = (b (μ - μ ν + ξ) (βa (α + γi + η + μ) + βi σ))/
  (μ (α + γi + η + μ) (μ + ξ + ρ) (γa + μ + σ));

Expre78 = (b βa (μ (-1 + ν) - ξ) + μ (μ + ξ + ρ) * 
  (γa + μ + σ))/(μ (μ + ξ + ρ) σ);

vars = Variables[Level[Expre78 && r0, {-1}]]

{b, α, βa, βi, γa, γi, η, μ, ν, ξ, ρ, σ}

There are no nonpositive cases

FindInstance[{Expre78 <= 0, b > 0, βa > 0, βi > 0, μ > 0, 
  0 < ν < 1, γa > 0, γi > 0, ξ > 0, ρ > 0, η >
    0, α > 0, σ > 0, r0 < 1}, vars]

(* {} *)

or

Reduce[{Expre78 <= 0, b > 0, βa > 0, βi > 0, μ > 0, 
  0 < ν < 1, γa > 0, γi > 0, ξ > 0, ρ > 0, η >
    0, α > 0, σ > 0, r0 < 1}]

(* False *)

There is at least one positive case

inst = FindInstance[{Expre78 > 0, 
   b > 0, βa > 0, βi > 0, μ > 0, 
   0 < ν < 1, γa > 0, γi > 0, ξ > 0, ρ > 0,
   η > 0, α > 0, σ > 0, r0 < 1}, vars]

(* {{b -> 7/2, α -> 1, βa -> 1, βi -> 3/2, γa -> 1,
   γi -> 1, η -> 1, μ -> 1, ν -> 1/2, ξ -> 1,
   ρ -> 1, σ -> 1}} *)

Expre78 /. inst[[1]]

5/4
$\endgroup$
8
  • $\begingroup$ Thank you. Could you attach examples showing where it is positive and negative? $\endgroup$
    – Math
    Jul 12, 2022 at 14:25
  • 1
    $\begingroup$ @Math please make an effort to understand the answer by BobHanlon, the examples are created there by using FindInstance. $\endgroup$
    – rhermans
    Jul 12, 2022 at 14:26
  • 1
    $\begingroup$ Look at the FindInstance expressions shown prior to evaluating the ReplaceAll $\endgroup$
    – Bob Hanlon
    Jul 12, 2022 at 14:27
  • $\begingroup$ @BobHanlon, I have added an addendum since I missed on important assumption. $\endgroup$
    – Math
    Jul 12, 2022 at 15:19
  • $\begingroup$ @BobHanlon Thank you for the update. I have one question; if Reduce[{Expre78 > 0, b > 0, βa > 0, βi > 0, μ > 0, 0 < ν < 1, γa > 0, γi > 0, ξ > 0, ρ > 0, η > 0, α > 0, σ > 0, r0 < 1}] outputs false then why when I change the reduce statement to Expre78 > 0 (or even Expre78 >= 0) it shows conditions? Shouldn't it output true? $\endgroup$
    – Math
    Jul 13, 2022 at 10:55

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.