How to calculate these limits with the LambertW function?

Question

For p>=2 I need to calculate a limit

 With[{p = 2}, Limit[E^(ProductLog[n p]/p)*(E^(-n^(-1 + 1/p) p^(-2 + 1/p) ProductLog[n p]^(1 - 1/p)) + 1/p - 1) + E^ProductLog[n p]/ p*(E^(-n^(-1 + 1/p) p^(-1 + 1/p) ProductLog[n p]^(1 - 1/p)) - 1), n -> Infinity]]

The limit is returned unevaluated.

Unfortunately, my efforts so far have stalled on finding a bug in Mathematica (versions 12 and 13), see Why do these identical limits give different results?

Then I found out that versions 10 and 11 don't have this bug. So I continued with them. However, I can't get a result.

My conjecture is that the limit is equal to -1/4 for p=2 and is equal to zero for p>=3.

 With[{p = 2}, Plot[E^(ProductLog[n p]/p)*(E^(-n^(-1 + 1/p) p^(-2 + 1/p) ProductLog[n p]^(1 - 1/p)) + 1/p - 1) + E^ProductLog[n p]/p*(E^(-n^(-1 + 1/p) p^(-1 + 1/p) ProductLog[n p]^(1 - 1/p)) - 1), {n, 1, 100000000000}]]

 With[{p = 3}, Plot[E^(ProductLog[n p]/p)*(E^(-n^(-1 + 1/p) p^(-2 + 1/p) ProductLog[n p]^(1 - 1/p)) + 1/p - 1) + E^ProductLog[n p]/p*(E^(-n^(-1 + 1/p) p^(-1 + 1/p) ProductLog[n p]^(1 - 1/p)) - 1), {n, 1, 100000000000}]]

My question is: How to calculate these limits with Mathematica ?

Versions 10 and 11 are able to calculate a similar limit

 Limit[E^(E^ProductLog[n] (-1 + E^(Sqrt[ProductLog[n]]/(2 Sqrt[n]))))*(E^(-(1/2) E^(ProductLog[n]/2))) , n -> Infinity]

Answer 1

Using my first approach from Why do these identical limits give different results? —

With[{p = 2}, 
 expr = E^(ProductLog[n p]/
        p)*(E^(-n^(-1 + 1/p) p^(-2 + 1/p) ProductLog[
            n p]^(1 - 1/p)) + 1/p - 1) + 
    E^ProductLog[n p]/
      p*(E^(-n^(-1 + 1/p) p^(-1 + 1/p) ProductLog[n p]^(1 - 1/p)) - 
       1) // FullSimplify]

Limit[expr /. n -> 1/n, n -> 0, Direction -> "FromAbove"]

(*  -(1/4)  *)

(Did you try it on this? You left no comment. With p = 3, I get 0, too.)

Answer 2

After substitution $$t=\frac{n}{W(p n)}$$ we have $$W(p n)=\frac{n}{t}$$ and $$\exp(W(p n))=\frac{p n}{W(p n)}=p t$$ where W is the LambertW function. Now the expression transforms to

 (-1 + E^(-p^(-1 + 1/p) t^(-1 + 1/p))) t + (-1 + E^(-p^(-2 + 1/p) t^(-1 + 1/p)) + 1/p) p^(1/p) t^(1/p)

If n tends to infinity, t also tends to infinity and as a result we get

 Assuming[p > 2, Limit[(-1 + E^(-p^(-1 + 1/p) t^(-1 + 1/p))) t + (-1 + E^(-p^(-2 + 1/p) t^(-1 + 1/p)) + 1/p) p^(1/p) t^(1/p), t -> Infinity]]

My conjecture is proven.