Merge two Legend

Question

Clear["Global`*"];
vars = {a, b, c, d, e, f};
cons = {1, 1, 1, 1, 1, 1};
rule = Thread[vars -> cons];

z1[x_, y_] := 
  a*f/Sqrt[1 + x/b]*(c*y + d)*((Sqrt[1 + x/b]/b - 1)*((y + 5)/6)^2 + 
     1);
z2[x_, y_] := 
 a*f/Sqrt[1 + x/b]*(c*y + 
    d)*((-(Sqrt[1 + x/b]/b) + 1)*Tanh[e*(y - 1)] + Sqrt[1 + x/b]/b)

z1Plt = Plot3D[
   z1[x, y] /. rule,
   {x, 10, 100}, {y, -5, 1},
   ColorFunction -> "Rainbow",
   PlotLegends -> Automatic
   ];
z2Plt = Plot3D[
   z2[x, y] /. rule,
   {x, 10, 100}, {y, 1, 10},
   PlotRange -> All,
   AxesLabel -> {"x", "y", "z"},
   ColorFunction -> "Rainbow",
   PlotLegends -> Automatic
   ];

Show[z2Plt, z1Plt]

As you can see, the two legend are separate. How do I merge them?

Answer 1

Use one Plot3D.

Plot3D[{ConditionalExpression[z1[x, y] /. rule, -5 <= y <= 1], 
  ConditionalExpression[z2[x, y] /. rule, 1 <= y <= 10]}, {x, 10, 
  100}, {y, -5, 10}, PlotRange -> All, AxesLabel -> {"x", "y", "z"}, 
 ColorFunction -> "Rainbow", PlotLegends -> Automatic]