-2
$\begingroup$

Does anyone know how to plot this image? I am writing an example for Kenmotsu's representation theorem , for $\varphi :% %TCIMACRO{\U{2102} }% %BeginExpansion \mathbb{C} %EndExpansion -\{0\}\rightarrow %TCIMACRO{\U{2102} }% %BeginExpansion \mathbb{C} %EndExpansion $, $\varphi (z)=\frac{1}{\bar{z}^{2}}.$ And this image corresponds to the surface with $\varphi (z)=-\frac{1}{\bar{z}^{2}}$ and $% H=1$. I am using Mathematica for only a couple days and I don't know what I'm supposed to write to generate it. I appreciate any advice and help! Thank you!

enter image description here

after a fairly long calculation I get to: enter image description here

and I assume that using this equation plots the image but I don't realize how I need to write this in Mathematica.

complex equation: enter image description here

Improve this question
$\endgroup$
9
  • $\begingroup$ Can you give more details? $\endgroup$
    – user64494
    Jun 9, 2022 at 10:10
  • $\begingroup$ Please post the details about the original complex equation instead of only the real equation. $\endgroup$
    – cvgmt
    Jun 9, 2022 at 12:24
  • $\begingroup$ it's posted now. $\endgroup$
    – user981656
    Jun 9, 2022 at 12:41
  • $\begingroup$ @user981656: Do you really mean an indefinite integral? $\endgroup$
    – user64494
    Jun 9, 2022 at 12:45
  • 3
    $\begingroup$ I meant in particular the code for the formula for $X(z)$, which you assume is correct. You are more likely to get more people to try to plot it for you if they can copy-paste instead of transcribing from browser to Mma. That said, incorrect code often reveals a misconception that you might like to have cleared up, which is a separate reason for posting code. (The first comment was meant to be generally helpful. You aren't required to post code, but some people will just skip a problem with no code and go on to something easier to deal with. Or go back to work. :) $\endgroup$
    – Michael E2
    Jun 9, 2022 at 15:39

2 Answers 2

Reset to default
3
$\begingroup$

(This is too long for a comment.)

If you look at the result of

(Re[f[u + I v]] + I Im[f[u + I v]]) (\[DifferentialD] u + I \[DifferentialD] v) // Expand
   I \[DifferentialD]u Im[f[u + I v]] - \[DifferentialD]v Im[f[u + I v]] +
   \[DifferentialD]u Re[f[u + I v]] + I \[DifferentialD]v Re[f[u + I v]]

this gives a hint on how to compute $\Re\int f(z,\bar{z})\,\mathrm dz$:

parts = Simplify[ComplexExpand[ReIm[1/z^3 {(1 - Conjugate[z]^-4)/(1 + (z Conjugate[z])^-2)^2,
                                           I (1 + Conjugate[z]^-4)/(1 + (z Conjugate[z])^-2)^2,
                                           (2 Conjugate[z]^-2)/(1 + (z Conjugate[z])^-2)^2} /.
                                    z -> u + I v], TargetFunctions -> {Re, Im}]]
   {{(u (-1 + u^4 - 2 u^2 v^2 - 3 v^4))/(1 + u^4 + 2 u^2 v^2 + v^4)^2,
     (v (-1 - 3 u^4 - 2 u^2 v^2 + v^4))/(1 + u^4 + 2 u^2 v^2 + v^4)^2},
    {-((v (1 - 3 u^4 - 2 u^2 v^2 + v^4))/(1 + u^4 + 2 u^2 v^2 + v^4)^2),
     (u + u^5 - 2 u^3 v^2 - 3 u v^4)/(1 + u^4 + 2 u^2 v^2 + v^4)^2},
    {(2 u (u^2 + v^2))/(1 + u^4 + 2 u^2 v^2 + v^4)^2,
     -((2 v (u^2 + v^2))/(1 + u^4 + 2 u^2 v^2 + v^4)^2)}}

FullSimplify[(MapThread[Integrate, {#, {u, v}}] & /@ parts) . {1, -1}]
   {(-u^2 + v^2)/(1 + (u^2 + v^2)^2), -((2 u v)/(1 + (u^2 + v^2)^2)), -(1/(1 + (u^2 + v^2)^2))}

which you should then multiply by a factor of $\frac2{H}$.

Verify the constant curvature property:

Simplify[ResourceFunction["MeanCurvature"][2 {(-u^2 + v^2)/(1 + (u^2 + v^2)^2),
                                              -((2 u v)/(1 + (u^2 + v^2)^2)),
                                              -(1/(1 + (u^2 + v^2)^2))}, {u, v}],
         u ∈ Reals && v ∈ Reals]
   1

As an exercise, why is the following result expected?

GroebnerBasis[Thread[{x, y, z} == 2 {(-u^2 + v^2)/(1 + (u^2 + v^2)^2),
                                     -((2 u v)/(1 + (u^2 + v^2)^2)),
                                     -(1/(1 + (u^2 + v^2)^2))}],
              {x, y, z}, {u, v}] // Simplify
   {x^2 + y^2 + z (2 + z)}
Improve this answer
$\endgroup$
0
$\begingroup$

This (?minimal) surface in three dimensions can be plotted in such ways:

ParametricPlot3D[{-(x^2 - y^2)*(1 - (x^2 + y^2)^2)/(1 + (x^2 + y^2)^2), 
-2*x*y*(1 - (x^2 + y^2)^2)/(1 + (x^2 + y^2)^2), 
(x^2 +  y^2)^2/(1 + (x^2 + y^2)^2)}, {x, -1, 1}, {y, -1, 1}]

enter image description here

or switching to the polar coordinates

ParametricPlot3D[{-(x^2 - y^2)*(1 - (x^2 + y^2)^2)/(1 + (x^2 + y^2)^2), -2*x*
y*(1 - (x^2 + y^2)^2)/(1 + (x^2 + y^2)^2), (x^2 +  y^2)^2/(1 + (x^2 + y^2)^2)} 
/. {x -> r*Cos[t], y -> r*Sin[t]}, {r, 0, 3/2}, {t, 0, 2*Pi}]

enter image description here

See the documentation for more info.

Improve this answer
$\endgroup$
1
  • $\begingroup$ The mention of Kenmotsu (as well as the other questions OP asked) was enough of a reminder for me that OP is dealing with surfaces of constant mean curvature, and minimal surfaces are of course a special case of that. $\endgroup$
    – J. M.'s eventual burnout ♦
    Jun 9, 2022 at 14:48

Not the answer you're looking for? Browse other questions tagged or ask your own question.