Parsing an expression for coefficients and more

Question

I have many expressions of this form:

expression = 1/96 (-26 I + 15 Sqrt[3]) c[1] - c[1]^3/(8 Sqrt[3]) + 
 1/120 I c[1]^5 + 5/96 (-5 I + 2 Sqrt[3]) c[3] + 
 1/480 (11 I + 135 Sqrt[3]) c[5]

For each c[a]^b term, I want to form a tuple with the coefficient to c[a]^b, argument of c[a]^b which is a, and power of c[a]^b which is b. I want a list of all these tuples.

So for this example, I want a function of expression that returns {{1/96 (-26 I + 15 Sqrt[3]), 1,1},{1/(8 Sqrt[3]),1,3},...}

How do I do this with Mathematica?

Answer 1

expression = 
  1/96 (-26 I + 15 Sqrt[3]) c[1] - c[1]^3/(8 Sqrt[3]) + 
   1/120 I c[1]^5 + 5/96 (-5 I + 2 Sqrt[3]) c[3] + 
   1/480 (11 I + 135 Sqrt[3]) c[5];

Cases[expression, coef_. * c[a_]^b_. :> {coef, a, b}, 1]

(* {{1/96 (-26 I + 15 Sqrt[3]), 1, 1}, 
    {-(1/(8 Sqrt[3])), 1, 3}, 
    {I/120, 1, 5}, 
    {5/96 (-5 I + 2 Sqrt[3]), 3, 1}, 
    {1/480 (11 I + 135 Sqrt[3]), 5, 1}} *)

EDIT: See the documentation for Default: "_. represents an argument that can be omitted" In this case, coef_. defaults to 1; b_. also defaults to 1

Default[Times]

(* 1 *)

Default[Power, 2]

(* 1 *)

EDIT 2: The example in your latest comment fails because the target is the whole expression rather than a part.

expr = 2 I c[1] Sin[Pi/7];

Cases[expr, coef_. * c[a_]^b_. :> {coef, a, b}, 1]

(* {{1, 1, 1}} *)

Since any result won't be affected by adding an arbitrary constant (say 1), do that for any input.

Cases[1 + expr, coef_. * c[a_]^b_. :> {coef, a, b}, 1]

(* {{2 I Sin[π/7], 1, 1}} *)

Answer 2

1/96 (-26 I + 15 Sqrt[3]) c[1] - c[1]^3/(8 Sqrt[3]) + 
1/120 I c[1]^5 + 5/96 (-5 I + 2 Sqrt[3]) c[3] + 
1/480 (11 I + 135 Sqrt[3]) c[5] //
Apply[List]//
Map[Replace[coef_. * c[a_]^b_. :> {coef, a, b}]]

{{(-26*I + 15*Sqrt[3])/96, 1, 1}, {-1/(8*Sqrt[3]), 1, 3}, {I/120, 1, 5}, {(5*(-5*I + 2*Sqrt[3]))/96, 3, 1}, {(11*I + 135*Sqrt[3])/480, 5, 1}}

also

1/4 Sqrt[3] c[1] - 1/6 I c[1]^3 + 1/12 (8 I + 3 Sqrt[3]) c[3]//
Apply[List]//
Map[Replace[coef_. * c[a_]^b_. :> {coef, a, b}]]

{{Sqrt[3]/4, 1, 1}, {-I/6, 1, 3}, {(8*I + 3*Sqrt[3])/12, 3, 1}}

meets your need.

Answer 3

Another way, as the comment @Henrik Schumacher said:

first = Function[t,FirstPosition[t , _?(# != 0 &)] ];
forKey = {first@#, Total@#}&;

CoefficientRules[1/4 Sqrt[3]c[1] - 1/6 I c[1]^3 + 1/12(8 I + 3 Sqrt[3]) c[3], Array[c, 5]]//
Association //
KeyValueMap[{#2,forKey@#1}&]//
Map[Flatten]

{{-I/6, 1, 3}, {Sqrt[3]/4, 1, 1}, {(2*I)/3 + Sqrt[3]/4, 3, 1}}