Equating coefficients of two expressions

Question

I have two symbolic Expressions and the both contain the same functions, as follows: $$ 3.12592+5.96272 \cos (2 \theta )+5.15739 \cos (4 \theta )+4.00413 \cos (6 \theta )+2.72961 \cos (8 \theta )+2.04608 \cos (10 \theta ) $$ and $$ 2. \text{$\Gamma $5} + 2. \text{$\Gamma $0} \cos (10 \theta )+2. \text{$\Gamma $1} \cos (8 \theta )+2. \text{$\Gamma $2} \cos (6 \theta )+2. \text{$\Gamma $3} \cos (4 \theta )+2. \text{$\Gamma $4} \cos (2 \theta ) $$ I want to solve for the Capital gammas by equating both equations coefficients. I tried Solve and it gave me an error "Equations may not give solutions for all "solve" variables" with the following solution: $$ \text{$\Gamma $5}\to -1. \text{$\Gamma $0} \cos (10. \theta )-1. \text{$\Gamma $1} \cos (8. \theta )-1. \text{$\Gamma $2} \cos (6. \theta )-1. \text{$\Gamma $3} \cos (4. \theta )-1. \text{$\Gamma $4} \cos (2. \theta )+2.98136 \cos (2. \theta )+2.5787 \cos (4. \theta )+2.00206 \cos (6. \theta )+1.3648 \cos (8. \theta )+1.02304 \cos (10. \theta )+1.56296 $$

I also tried Coefficient but it cannot extract the constant from the expression, CoefficientList does not work in this case as it is not a polynomial. Any Ideas? My code:

A=0.05;
zl=50;
z0=500;
n=10;
\[CapitalGamma]=0;
sec\[Theta]m=Cosh[1/n*ArcCosh[Abs[Log[zl/z0]/(2*0.05)]]];

glist=Table[Symbol["\[CapitalGamma]" <> ToString[i]], {i,0, n/2}];
conum=Range[n,Boole[OddQ[n]],-2];
For[i=1,i<=Length[glist],i++,
    \[CapitalGamma]= N[2]*glist[[i]] * Cos[conum[[i]]\[Theta]] + \[CapitalGamma]
    ];

TrigReduce[ChebyshevT[10,sec\[Theta]m*Cos[\[Theta]]]]
\[CapitalGamma]
Solve[TrigReduce[ChebyshevT[10,sec\[Theta]m*Cos[\[Theta]]]] == \[CapitalGamma], glist]

Answer 1

Another way with SolveAlways

f1 = 5.96272 Cos[2 θ] + 5.15739 Cos[4 θ] + 
   4.00413 Cos[6 θ] + 2.72961 Cos[8 θ] + 
   2.04608 Cos[10 θ] + 3.12592;

f2 = 2 Γ0 Cos[10 θ] + 
   2 Γ1 Cos[8 θ] + 
   2 Γ2 Cos[6 θ] + 
   2 Γ3 Cos[4 θ] + 
   2 Γ4 Cos[2 θ] + 2 Γ5;

vars = Variables[f2][[7 ;;]]

(*   {Cos[2 θ], Cos[4 θ], Cos[6 θ], Cos[8 θ], 
 Cos[10 θ]}   *)

SolveAlways[f1 == f2, vars]

(*   {{Γ0 -> 1.02304, Γ1 -> 
   1.36481, Γ2 -> 2.00207, Γ3 -> 
   2.5787, Γ4 -> 2.98136, Γ5 -> 1.56296}}   *)

Answer 2

To be able to use "CoefficientList" we must first transform your equation to a polynomial by e.g. Lefthand Side-Righthand Side. Then we replace Cos[i theta] by e.g. c^i:

eq = {5.96272 Cos[2 θ] + 5.15739 Cos[4 θ] + 
    4.00413 Cos[6 θ] + 2.72961 Cos[8 θ] + 
    2.04608 Cos[10 θ] + 
    3.12592 - (2 Γ0 Cos[10 θ] + 
      2 Γ1 Cos[8 θ] + 
      2 Γ2 Cos[6 θ] + 
      2 Γ3 Cos[4 θ] + 
      2 Γ4 Cos[2 θ] + 2 Γ5)} /. 
  Cos[i_ θ] -> c^i

Now we can apply CoefficientList:

eq1= CoefficientList[eq, c][[1]]

Finally we solve for the gammas by equating the coefficients to zero:

Solve[Thread[ eq1 == 0], {Γ0, Γ1, Γ2, Γ3, Γ4, Γ5}]

Answer 3

Here's a way that's a bit silly but which should work. (I'm on a computer without MM on it right now, so if the code doesn't work please ping me in the comments and I'll fix it as soon as I'm able.)

expr = {5.96272 Cos[2 θ] + 5.15739 Cos[4 θ] + 
4.00413 Cos[6 θ] + 2.72961 Cos[8 θ] + 
2.04608 Cos[10 θ] + 
3.12592 - (2 Γ0 Cos[10 θ] + 
  2 Γ1 Cos[8 θ] + 
  2 Γ2 Cos[6 θ] + 
  2 Γ3 Cos[4 θ] + 
  2 Γ4 Cos[2 θ] + 2 Γ5)}
Solve[Table[FourierCosCoefficient[expr, θ, i] == 0, {i, 0, 10}], {Γ0, Γ1, Γ2, Γ3, Γ4, Γ5}]

This relies on the fact that your expressions are already effectively Fourier cosine series.