2
$\begingroup$

I want to plot the following function on Mathematica, and I gave it a go on wolframalpha.

Bessel[n,z] is the usual form, but I am not sure how to use this to compute the following plot:

\begin{equation} u(r,t)=\frac{\alpha J_{4}(i\sqrt{2}r)}{J_{4}\big(\frac{100*2}{\alpha}\big)}e^{-16t^2} \end{equation}

I tried

BesselJ[4, I Sqrt[2] x]/BesselJ[4, 200]

But I don't know how to include the zeros defined by $\alpha$

Any help appreciated!

where $\alpha$ are the zeros of the Bessel function.

$\endgroup$
2
  • 2
    $\begingroup$ By "zeros of the Bessel function," do you mean alpha = BesselJZero[n, k]? For n = 4 for k = 1, 2, 3,....? $\endgroup$
    – Michael E2
    May 21 at 15:26
  • $\begingroup$ Yes, precisely. $\endgroup$
    – Vangsnes
    May 21 at 15:27

1 Answer 1

5
$\begingroup$
Clear["Global`*"]

u[x_, t_, α_] := α*BesselJ[4, I Sqrt[2] x]/BesselJ[4, 200/α]*
  E^(-16 t^2)

u[x, t, α] == -u[x, t, -α]

(* True *)

u[x, t, α] == u[x, -t, α]

(* True *)

u[x, t, α] == u[-x, t, α]

(* True *)

Manipulate[
 Plot3D[u[x, t, α],
  {x, -5, 5}, {t, -2, 2},
  AxesLabel -> Automatic,
  ClippingStyle -> None],
 {{α, 1}, 0.05, 5, 0.05, Appearance -> "Labeled"}]

enter image description here

EDIT: For α = BesselJZero[4, k]

Manipulate[
 α = BesselJZero[4, k];
 Plot3D[u[x, t, α], {x, -5, 5}, {t, -2, 2},
  AxesLabel -> Automatic,
  ClippingStyle -> None,
  PlotLabel -> StringForm["α = `` = ``", α, α // N],
  WorkingPrecision -> 15],
 {{k, 1}, Range[10], ControlType -> SetterBar}]

enter image description here

$\endgroup$
1

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.