How can I label different subcategories in different groups in BoxWhiskerChart?

Question

Subcategories in different groups have different names.

How can I adjust the settings of ChartLabels? Or is there another way?

data = {{RandomInteger[{0, 100}, 100],
    RandomInteger[{0, 100}, 100]}, {RandomInteger[{0, 100}, 100],
    RandomInteger[{0, 100}, 100]}};
BoxWhiskerChart[data,
 ChartLabels -> {{"Group1", "Group2"}, {"a", "b", "c", "d"}}]

Very confusing! Neither approach works if the number of subgroups is different!

data = {{RandomInteger[{0, 100}, 100],RandomInteger[{0, 100}, 100],
    RandomInteger[{0, 100}, 100]}, {RandomInteger[{0, 100}, 100],
    RandomInteger[{0, 100}, 100]}};
BoxWhiskerChart[data,
 ChartLabels -> {{"Group1", "Group2"}, {"a", "b", "c", "d", "e"}}]

Answer 1

Clear["Global`*"]

SeedRandom[1234];

data = {
   {RandomInteger[{0, 100}, 100], 
    RandomInteger[{0, 100}, 100]}, 
   {RandomInteger[{0, 100}, 100], 
    RandomInteger[{0, 100}, 100]}};

colors = {
   RGBColor[0.982864, 0.7431472, 0.3262672], 
   RGBColor[0.4992, 0.5552, 0.8309304]};

BoxWhiskerChart[Flatten[data, 1],
 ChartStyle -> colors, ChartLabels -> {"a", "b", "c", "d"},
 Epilog -> {
   Text[Style["Group1", 9], Scaled@{0.28, -0.15}],
   Text[Style["Group2", 9], Scaled@{0.74, -0.15}]},
 ImagePadding -> {{Automatic, 5}, {30, 5}}]

Answer 2

SeedRandom[1]
data = {{RandomInteger[{0, 100}, 100], RandomInteger[{0, 100}, 100]}, 
  {RandomInteger[{0, 100}, 100], RandomInteger[{0, 100}, 100]}};

labels = TakeList[ {"a", "b", "c", "d"}, Length /@ data];

You can wrap each data series with Labeled to attach desired labels:

labeleddata = MapThread[Labeled] /@ Transpose[{data, labels}];

BoxWhiskerChart[labeleddata, ChartLabels -> {{"Group1", "Group2"}, Automatic}]