4
$\begingroup$

I wonder if Mathematica can be used to numerically solve the following nonlinear integral equation?

$\lambda^2(t)-\frac{1}{\lambda^4(t)}+\frac{2}{R_0^2} \int_{R_0}^{R_0+u_0t} R \left[\frac{\lambda^2(t)}{\lambda^4\big(\frac{R-R_0}{u_0}\big)}-\frac{\lambda^2\big(\frac{R-R_0}{u_0}\big)}{\lambda^4(t)} \right]dR =F(t)\,,\quad t\in[0,T]$, where $R_0$, $u_0$, and $F(t)$ are given.

$\endgroup$
3
  • 2
    $\begingroup$ Welcome to Mathematica.SE! I suggest the following: 1) As you receive help, try to give it too, by answering questions in your area of expertise. 2) Take the tour! 3) When you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge. Also, please remember to accept the answer, if any, that solves your problem, by clicking the checkmark sign! $\endgroup$
    – Michael E2
    Commented May 18, 2022 at 19:32
  • 4
    $\begingroup$ May be we can solve it with Mathematica. If $R_0, u_0, F(t)$ are given then how they look like? $\endgroup$ Commented May 19, 2022 at 2:49
  • 1
    $\begingroup$ I suggest you try converting this to an ODE, which I believe is possible. In any case, please provide values for your many constants and for the function, F. $\endgroup$
    – bbgodfrey
    Commented May 19, 2022 at 14:49

1 Answer 1

6
$\begingroup$

This integral equation can be transformed into a system of ODEs, after which it can be solved with NDSolve. Begin with the integral equation,

eqi = λ[t]^2 - λ[t]^-4 + (2 r0^-2) (λ[t]^2 i1[t] - λ[t]^-4 i2[t]) == f[t]

where i1[t] and i2[t] are integrals of r λ[(r - r0)/u0]^-4 and r λ[(r - r0)/u0]^2, respectively, over {r, r0, r0 + u0 t}. Derivatives of these two are

di1 = D[i1[t], t] /. 
    i1 -> Function[t, Integrate[r λ[(r - r0)/u0]^-4, {r, r0, r0 + u0 t}]]
di2 = D[i2[t], t] /. 
    i2 -> Function[t, Integrate[r λ[(r - r0)/u0]^2, {r, r0, r0 + u0 t}]]
(* (u0 (r0 + t u0))/λ[t]^4 *)
(* u0 (r0 + t u0) λ[t]^2 *)

Once f[t] and the various constants are specified, the integral equation can be solved by

NDSolve[{eqi, i1'[t] = di1, i2'[t] == di2, i1[0] == 0, i2[0] == 0},
    λ[t], {t, 0, T}]

Alternatively, i1[t] and i2[t] can be eliminated to yield a single second-order ODE,

Simplify[di1 == First@Simplify@D[SolveValues[eqi, i1[t]], t] /. i2'[t] -> di2];
eq = Simplify[di2 == First@Simplify@D[SolveValues[%, i2[t]], t]]
(* u0 (r0 + t u0) λ[t]^2 == (1/(12 [λ'[t]^2)) r0^2 λ[t]^3 
  (3 λ[t] f'[t] λ'[t]^2 - 8 f[t] λ'[t]^3 + λ[t]^2 (λ'[t] f''[t] - f'[t] y''[t])) *)

although initial conditions for λ[t] also are needed.

eqi /. t -> 0 /. {i1[0] -> 0, i2[0] -> 0}
(* -(1/λ[0]^4) + λ[0]^2 == f[0] *)

Solve[D[eqi, t] /. {i1'[t] -> di1, i2'[t] -> di2} /. t -> 0 
    /. {i1[0] -> 0, i2[0] -> 0}, λ'[0]] [[1, 1]]
(* λ'[0] -> (λ[0]^5 f'[0])/(2 (2 + λ[0]^6)) *)

As an example,

NDSolveValue[{eqi, i1'[t] == di1, i2'[t] == di2, i1[0] == 0, i2[0] == 0} /. 
    {r0 -> 1, u0 -> 1, f[t] -> Sin[t]}, {λ[t], i1[t], i2[t]}, {t, 0, 20}]
Plot[%[[1]], {t, 0, 20}, PlotRange -> All, 
    AxesLabel -> {t, λ}, LabelStyle -> {15, Bold, Black}]
Plot[Evaluate[%%[[2 ;;]]], {t, 0, 20}, AxesLabel -> {t, i}, 
    LabelStyle -> {15, Bold, Black}]

enter image description here

enter image description here

The second-order ODE with constants as above and initial conditions {λ[0] == 1, λ'[0] == 1/6} gives the same result for λ[t].

$\endgroup$
3
  • 1
    $\begingroup$ Thank you very much! The key idea was to transform it to a system of linear ODEs. $\endgroup$
    – Arash
    Commented May 21, 2022 at 13:43
  • 1
    $\begingroup$ @Arash That is correct. If you found the answer helpful, please up-vote and accept it. Thanks. $\endgroup$
    – bbgodfrey
    Commented May 21, 2022 at 15:45
  • $\begingroup$ It was certainly helpful. This was actually my first question/post here. And I just up-voted. $\endgroup$
    – Arash
    Commented May 21, 2022 at 21:47

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.