2
$\begingroup$

How can I get a symbolic solution from the following differential equation? I don't know in that case using a change of variable is a good idea. I have tried in maple as well but the form of the solution was not in my desire.

wave = (3 Derivative[1][a][t]/a[t] Derivative[1][T][t]) + 
   T[t] (\[CapitalOmega]^2/
      a[t]^2 - (6 Derivative[1][a][t]^2/
        a[t]^2) - (2 (a^\[Prime]\[Prime])[t]/a[t])) + (
    T^\[Prime]\[Prime])[t] == 0
a[t_] := t^\[Alpha];
DSolve[(-((2 (-1 + \[Alpha]) \[Alpha])/t^2) - (6 \[Alpha]^2)/t^2 + 
      t^(-2 \[Alpha]) \[CapitalOmega]^2) T[t] + (
   3 \[Alpha] Derivative[1][T][t])/t + (T^\[Prime]\[Prime])[t] == 
  0, {T[t], T[t]}, {t}]

Thank you!

$\endgroup$
2
  • $\begingroup$ what is wave for? where is it used? $\endgroup$
    – Nasser
    May 13 at 10:09
  • $\begingroup$ It's gravitational waves OK. But why do you have it is my question. Where is it used in the DSolve command? If it is not relevant variable and not used, why show it in the question? It can make things confusing to the reader. $\endgroup$
    – Nasser
    May 13 at 10:26

2 Answers 2

8
$\begingroup$

DSolve can solve if we perform some algebraic manipulations:

eq = (-((2 (-1 + \[Alpha]) \[Alpha])/t^2) - (6 \[Alpha]^2)/t^2 + 
 t^(-2 \[Alpha]) \[CapitalOmega]^2) T[t] + (3 \[Alpha] T'[t])/t + T''[t];
eq1 = (eq*t^2 // Simplify // Expand) == 0

$$\Omega ^2 t^{2-2 \alpha } T(t)+t^2 T''(t)+3 \alpha t T'(t)-8 \alpha ^2 T(t)+2 \alpha T(t)=0$$

If we change exponent from: $2-2 \alpha$ to $z$ then:

 eq3 = 2 \[Alpha] T[t] - 8 \[Alpha]^2 T[t] + 
t^z \[CapitalOmega]^2 T[t] + 3 t \[Alpha] T'[t] + t^2 T''[t] == 0;
DSolve[eq3, T[t], t] /. z -> 2 - 2 \[Alpha] // FullSimplify
(*Go back from z to 2-2 \alpha*)

$$T(t)=\left(t^{2-2 \alpha }\right)^{\frac{3}{4}+\frac{1}{2 (-1+\alpha )}} (2-2 \alpha )^{-\frac{3}{2}+\frac{1}{1-\alpha }} \Omega ^{\frac{3}{2}+\frac{1}{-1+\alpha }} \left(J_{\frac{\sqrt{1+\alpha (-14+41 \alpha )}}{2-2 \alpha }}\left(\frac{\sqrt{t^{2-2 \alpha }} \Omega }{1-\alpha }\right) c_2 \Gamma \left(1+\frac{\sqrt{1+\alpha (-14+41 \alpha )}}{2-2 \alpha }\right)+J_{\frac{\sqrt{1+\alpha (-14+41 \alpha )}}{2 (-1+\alpha )}}\left(\frac{\sqrt{t^{2-2 \alpha }} \Omega }{1-\alpha }\right) c_1 \Gamma \left(1+\frac{\sqrt{1+\alpha (-14+41 \alpha )}}{2 (-1+\alpha )}\right)\right)$$

$\endgroup$
1
  • 1
    $\begingroup$ Just wow, well done ☺️ $\endgroup$
    – Ella7
    May 13 at 15:23
3
$\begingroup$

Mathematica can't solve this

ClearAll[α, t, Ω, T]
ode = (-((2 (-1 + α) α)/t^2) - (6 α^2)/t^2 + t^(-2 α) Ω^2) T[t] + (3 α T'[t])/t + T''[t] == 0;
DSolve[ode, T[t], t]

Mathematica graphics

It can however solve it when α is given a specific value

 DSolve[ode /. {α -> 1}, T[t], t]

Mathematica graphics

 DSolve[ode /. {α -> 2}, T[t], t]

Mathematica graphics

DSolve[ode /. {α -> 1/2}, T[t], t]

Mathematica graphics

You said you tried Maple but did not like its solution. Why? Maple can solve this without given specific value for α and its solution agrees with Mathematica above for specific values of α :

local Omega:
ode := (-((2 (-1 + alpha)*alpha)/t^2) - (6*alpha^2)/t^2 + t^(-2* alpha)* Omega^2)*T(t)+ (3 *alpha* diff(T(t),t))/t + diff(T(t),t$2)= 0;
dsolve(ode)

enter image description here

This seems to be limitation of DSolve at this time.

$\endgroup$
2
  • $\begingroup$ @NajibeBorhani if the solution is valid, I am sure there is transformation of these special function to rewrite them in terms of other special functions. I mean you might be able to convert Maple's solution using Bessels's to the same as Mathematica's using Bessel and Gamma. This becomes different issue. $\endgroup$
    – Nasser
    May 13 at 10:30
  • $\begingroup$ @NajibeBorhani see convert/to_special_functions at Maple's site. But there is no guarantee it will be able to convert the solution to the form you want but have to play with it and see. $\endgroup$
    – Nasser
    May 13 at 10:46

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.