Is it how you do a projection? Is it a Projection? I don’t know what this is

Question

I don't really know, if this is a projection. Maybe you can tell me. . . From the parametric equations

{ 1.5 Cos[0.82 Cosh[x]] + 1.5 Sin[0.33 Sinh[x]], -1.5 Cos[0.33 Cosh[x]] + 1.5 Sin[0.82 Sinh[x]]}

with x going from $-2.15 \Pi$ to $2.15 \Pi$.

I substituted into the parametric equations of the sphere the above equations like this.

{ Cos[x] Cos[y], Cos[x] Sin[y], Sin[x] } /. x -> 1.5 Cos[0.82 Cosh[a]] + 1.5 Sin[0.33 Sinh[a]]

{ Cos[1.5 Cos[0.82 Cosh[a]] + 1.5 Sin[0.33 Sinh[a]]] Cos[y], Cos[1.5 Cos[0.82 Cosh[a]] + 1.5 Sin[0.33 Sinh[a]]] Sin[y], Sin[1.5 Cos[0.82 Cosh[a]] + 1.5 Sin[0.33 Sinh[a]]] } /. y ->  -1.5 Cos[0.33 Cosh[b]] + 1.5 Sin[0.82 Sinh[b]]

And then I have added x to all the letters a and b to the result which in the end gave me something like that

Manipulate[Show[ParametricPlot3D[ {Cos[x] Cos[y], Cos[x]Sin[y],Sin[x]}, {x, 0, 2Pi}, {y, 0, 2Pi}, PlotStyle->{Red,Opacity[0.25]}, Mesh->None],ParametricPlot3D[{ Cos[1.5 Cos[0.82 Cosh[a x]] + 1.5 Sin[0.33 Sinh[a x]]] Cos[-1.5 Cos[0.33 Cosh[b x]] + 1.5 Sin[0.82 Sinh[b x]]], Cos[1.5 Cos[0.82 Cosh[a x]] + 1.5 Sin[0.33 Sinh[a x]]] Sin[-1.5 Cos[0.33 Cosh[b x]] + 1.5 Sin[0.82 Sinh[b x]]], Sin[1.5 Cos[0.82 Cosh[a x]] + 1.5 Sin[0.33 Sinh[a x]]] } , {x,0,1}, PlotStyle->Blue,Mesh->100,PlotPoints->100]],{a,-Pi,Pi.01}, {b,-Pi,Pi,0.1}]

and then I have set the sliders so that both a and b are at Pi.

When I look at the pole of this sphere it looks a little bit like as if the following parametric plot

ParametricPlot[{ 1.5 Cos[0.82 Cosh[x]] + 1.5 Sin[0.33 Sinh[x]], -1.5 Cos[0.33 Cosh[x]] + 1.5 Sin[0.82 Sinh[x]]}, {x, -2.15Pi, 2.15Pi}, PlotPoints->215, PlotStyle->Blue]

is “mapped” or “projected” onto the sphere.

Answer 1

This is a composition of mapping,not a projection.

$$(a,b)\to (u,v) \to (x,y,z)$$

We can illustrate such composition of mapping as below.

Clear["Global`*"];
DynamicModule[{p = {1, 1}},
 {Slider2D[Dynamic[p], {{-Pi, -Pi}, {Pi, Pi}}], 
  Dynamic@ParametricPlot[{u, 
       v} /. {u -> 1.5 Cos[0.82 Cosh[a x]] + 1.5 Sin[0.33 Sinh[a x]], 
       v -> -1.5 Cos[0.33 Cosh[b x]] + 
         1.5 Sin[0.82 Sinh[b x]]} /. {a -> p[[1]], b -> p[[2]]}, {x, 
     0, 1}, PlotStyle -> Blue, Mesh -> None, PlotPoints -> 30, 
    PlotRange -> 4, AxesOrigin -> {0, 0}, Ticks -> None, 
    AxesLabel -> {"u", "v"}], 
  Dynamic@Show[
    ParametricPlot3D[{Cos[u] Cos[v], Cos[u] Sin[v], 
        Sin[u]} /. {u -> 
         1.5 Cos[0.82 Cosh[a x]] + 1.5 Sin[0.33 Sinh[a x]], 
        v -> -1.5 Cos[0.33 Cosh[b x]] + 
          1.5 Sin[0.82 Sinh[b x]]} /. {a -> p[[1]], b -> p[[2]]}, {x, 
      0, 1}, PlotStyle -> Blue, Mesh -> None, PlotPoints -> 30, 
     SphericalRegion -> True, PlotRange -> 1], 
    ParametricPlot3D[{Cos[x] Cos[y], Cos[x] Sin[y], Sin[x]}, {x, 0, 
      2 Pi}, {y, 0, Pi}, PlotStyle -> {Red, Opacity[0.5]}, 
     Mesh -> None, PerformanceGoal -> "Quality"], Boxed -> False, 
    Ticks -> None, AxesLabel -> {"x", "y", "z"}]}]

Answer 2

There are several errors in your plotting code (bmf pointed out pi, PlotStyleBlue should have a ->, PlotPoint should have an s).

I'm interpreting your question as "what's a 3D curve whose projection onto the plane is the same as this 2D curve". In that case, it seems to be on a sphere of radius 9.32:

Remove[curve2d,curve3d,radsqd]
curve2d = 1.5{Cos[0.82Cosh@x]+Sin[0.33Sinh@x],-Cos[0.33Cosh@x]+Sin[0.82Sinh@x]};
radsqd = MaxValue[Plus@@(curve2d^2),x]
curve3d = Append[curve2d,Sqrt[MaxValue[radsqd,x]-Plus@@(curve2d^2)]];
Manipulate[Show[
 ParametricPlot3D[{{0,0,0},curve3d},{x,-2.15Pi,2.15Pi},
  PerformanceGoal->"Quality",PlotRange->All,PlotStyle->Thin,
  ViewPoint->Top,ViewProjection->"Orthographic"],
 ParametricPlot3D[curve3d,{x,-a,a},PerformanceGoal->"Quality"]],
{{a,.1},0,2.15Pi}]

Is there some more complicated equation solving that needs to be done in order to find such a curve?