How to create a list of lists using Range[]

Question

Given an integer, say 20, how can I create the following irregular list of lists?

lst={5,7,3,5};
Range[#]&/@lst;

generates this:

{{1, 2, 3, 4, 5}, {1, 2, 3, 4, 5, 6, 7}, {1, 2, 3}, {1, 2, 3, 4, 5}}

I like to have the following list of lists:

{{1,2,3,4,5}, {6,7,8,9,10,11,12}, {13,14,15}, {16,17,18,19,20}}

If the list of lists was a regular sequence, I could use:

Partition[Range[20], 5]] 

Answer 1

lst = {5, 7, 3, 5};

1. First way:

We have

Internal`PartitionRagged[Range@20, lst]

2. Another one

We have

TakeList[Range@20, lst]

The output is:

Answer 2

This is the classic use-case for FoldPairList:

FoldPairList[TakeDrop, Range[20], {5, 7, 3, 5}]

Alternatively, I recently made a resource function for the situation where you want to split at specific positions:

ResourceFunction["SplitAtPositions"][Range[20], {5, 12, 15}, After]

Answer 3

Although TakeList is the built-in function to do this, but if you want to do it randomly then a bit of setup would be helpful:

n = 20; (* list length *)
k = 5; (* # parts of list *)
alist = Range[n]
parts = IntegerPartitions[n, {k}]
SeedRandom[1];
TakeList[alist, RandomChoice[parts]]

{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}, {11, 12, 13, 14}, {15, 16, 17, 
  18}, {19, 20}}

Answer 4

Sightly long.

lst={5,7,3,5};
len = Total@lst;
index = Accumulate[lst];
diff = Join[{{1,lst[[1]]}}, Transpose[{index[[;;-2]]+1, index[[2;;]]}]];
(Range@len)[[#1;;#2]]&@@@diff

Answer 5

Starting from your two lines:

lst = {5, 7, 3, 5};
ints = Range[#] & /@ lst;

ints + Flatten[{0, Drop[Accumulate[lst], -1]}]
{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10, 11, 12}, {13, 14, 15}, {16, 17, 18, 19, 20}}

Answer 6

We create a RangePartition function:

RangePartition[list_List] := MapAt[{#[[1]] + 1, #[[2]]} &, Partition[Flatten[Append[{1}, Accumulate[list]]], 2, 1], Outer[List, Range[2, Length[list]]]]

Also, we create a RangeList function:

RangeList[list_List] := Block[{arraysymb, symb, rangesymb,rangelist},
arraysymb = Array[Subscript[symb, ##] &, 2, 1];
rangesymb = Array[Subscript[symb, ##] &, 2, 1, HoldForm[Range]];
rangelist = 
ReleaseHold[ReplaceAll[Thread[arraysymb -> list]][rangesymb]];
Return[rangelist]]

Then:

Map[RangeList, RangePartition[lst]]

(*{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10, 11, 12}, {13, 14, 15}, {16, 17, 18,19, 20}}*)

Answer 7

Further alternatives:

ClearAll[f, g, h]

f = FoldList[#2 + Last @ # &] @* Range;

g = Range @ # + Prepend[0] @ Most @ Accumulate @ # &;

h = Total @* Through @* {Range, Prepend[0] @* Most @* Accumulate}

Examples:

f @ lst

{{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10, 11, 12}, {13, 14, 15}, {16, 17, 18, 19, 20}}

f @ lst == g @ lst == h @ lst

True