0
$\begingroup$

Find the mapping of circle using confirmal mapping ( joukowski tansformation method) Assume w= z+1/z 〖z=re〗^iθ = 〖r(cosθ+isinθ)〗^1 ( a Circle with radius r and center (0,0))

$\endgroup$
11
  • 1
    $\begingroup$ You might want to have a look at the answers here 119516. Related threads are 266643, 229505, also 244912 $\endgroup$
    – bmf
    Apr 17, 2022 at 20:59
  • 2
    $\begingroup$ @bmf This probably could be migrated to math.SE. But we now have an example of what I will call the Conformal Elephant Method, as a posted solution to one of this spate of essentially identical do-my-homework questions. So it's easy just to close as a duplicate. $\endgroup$ Apr 17, 2022 at 21:10
  • 1
    $\begingroup$ @DanielLichtblau ah yes. Nobody can forget about Ellie and her complex behavior patterns :) $\endgroup$
    – bmf
    Apr 17, 2022 at 21:12
  • 1
    $\begingroup$ @bmf Yes, Ellie does seem to be making the rounds. She may need to pack a trunk... $\endgroup$ Apr 17, 2022 at 21:14
  • 2
    $\begingroup$ Likewise @bmf. Though maybe not Ellie on a rainbow, I'd be afraid she might get punctured by a unicorn or something. $\endgroup$ Apr 17, 2022 at 21:39

1 Answer 1

10
$\begingroup$

We can use Manipulate to find such suitable Circle.The circle through {1,0} and center by w(one possible w={-.2, .4}). The Joukowsky tansformation mapping such circle to a closed curve like the wings of an airplane.

Manipulate[
 Block[{w = {1, I} . pt, r = Abs[w - 1], z = w + r*Exp[I*t]}, 
  GraphicsRow@{Graphics[{Circle[pt, r], Text[pt, pt], 
      AbsolutePointSize[5], {Red, Point[{1, 0}]}}, PlotRange -> 3, 
     Axes -> True], 
    ParametricPlot[ReIm[z + 1/z], {t, 0, 2 π}, 
     PlotRange -> 3]}], {{pt, {-.2, .4}}, {-1, -1}, {1, 1}}, 
 ControlPlacement -> Top]

enter image description here

*

Manipulate[
 Block[{w1, r1, z1, pt2, w2, r2, z2, t, c}, w1 = {1, I} . pt1; 
  r1 = Abs[w1 - 1]; z1 = w1 + r1*Exp[I*t];
  pt2 = (1 - c)*{1, 0} + c*pt1;
  w2 = {1, I} . pt2; r2 = Abs[w2 - 1]; z2 = w2 + r2*Exp[I*t];
  λ0 = 
   SolveValues[First[(1 - c)*{1, 0} + c*pt1] == 0 /. pt1 -> {-.2, .4},
      c][[1]];
  GraphicsRow@{ParametricPlot[{ReIm[z1], ReIm[z2]}, {t, 0, 
      2 π}, {c, λ, 1}, MeshFunctions -> {#4 &}, 
     Mesh -> {{λ0}}, MeshStyle -> White, PlotRange -> 2, 
     PerformanceGoal -> "Quality", 
     Epilog -> {Point[pt1], Point[pt2 /. c -> λ], 
       Line[{pt1, pt2 /. c -> λ}], Dotted, 
       Line[{pt2 /. c -> λ, {1, 0}}]}, PlotStyle -> Magenta], 
    ParametricPlot[{ReIm[(z1 + 1/z1)/2], ReIm[(z2 + 1/z2)/2]}, {t, 0, 
      2 π}, {c, λ, 1}, MeshFunctions -> {#4 &}, 
     Mesh -> {{λ0}}, MeshStyle -> White, PlotRange -> 2, 
     PerformanceGoal -> "Quality", 
     PlotStyle -> Magenta]}], {{pt1, {-.2, .4}}, {-1, -1}, {1, 
   1}}, {{λ, λ0}, 0, 1 - $MachineEpsilon}, 
 ControlPlacement -> Top]

enter image description here

$\endgroup$
6
  • $\begingroup$ Really wonderful stuff!!! $\endgroup$
    – bmf
    Apr 17, 2022 at 22:35
  • $\begingroup$ @bmf Thanks your upvote! I don't know how to make the text and the graphics row looks good. $\endgroup$
    – cvgmt
    Apr 17, 2022 at 22:42
  • $\begingroup$ yes, it's a bit tricky as it would seem. but I have to say they don't look bad and things are very clear. if I manage to come up with something, I will leave a comment :) $\endgroup$
    – bmf
    Apr 17, 2022 at 22:45
  • $\begingroup$ update: some partial progress -not very satisfactory- can be made as follows: Manipulate[Block[{w = pt[[1]] + pt[[2]]*I, r = Abs[pt[[1]] + pt[[2]]*I - 1], z = w + r*Exp[I*t]}, GraphicsRow@{Graphics[{Circle[pt, r], Text[pt, pt, {-2, -10}, {1, 0}], AbsolutePointSize[5], {Red, Point[{1, 0}]}}, PlotRange -> 3, Axes -> True], ParametricPlot[ReIm[z + 1/z], {t, 0, 2 \[Pi]}, PlotRange -> 3]}], {{pt, {-.2, .4}}, {-1, -1}, {1, 1}}, ControlPlacement -> Top] Did you have in mind something like that or did I misunderstand? $\endgroup$
    – bmf
    Apr 17, 2022 at 23:48
  • 2
    $\begingroup$ Upvoted, begrudgingly. I do not much like having responses to do-my-homework when no effort on the part of the poster is shown. But this is a nice answer all the same. $\endgroup$ Apr 18, 2022 at 17:45

Not the answer you're looking for? Browse other questions tagged or ask your own question.