Plot issue : put a legend instead of a top label

Question

I have an issue about putting a legend consisted of a text and numerical value instead of a label.

For example, with this command line :

ωBD=9900;
pl = ListLinePlot[{ScaleFactorPast,ScaleFactorFuture},PlotStyle->{Blue,Blue},Frame->True,FrameLabel->{"t","a(t)"},LabelStyle->{FontSize->20,FontFamily->"Helvetica",Black,Bold},PlotRange->All, ImageSize->{600},Epilog->{Style[Text["Now",{0,1.4}],24],PointSize[.02],Point[{0, 1}]}, PlotLabel -> Row[{Subscript[ω, BD], "=", ωBD}]]

which generates the following plot :

Now, I would like to have the same label (text=omega_BD = numerical value associated) but in a legend box with same rendring than for the simple label printing.

I would like to put it either with a smart way (like in Python Matplotlib loc='best' or at the bottom right (where there is some void).

I don't know how to perform this, i.e put the initial label into a legend with ListLinePlot function.

Any tracks or suggestions are welcome.

UPDATE 1 : This solution doesn't work :

 pl = ListLinePlot[{ScaleFactorPast,ScaleFactorFuture},PlotStyle->{Blue,Blue},Frame->True,FrameLabel->{"t","a(t)"},LabelStyle->{FontSize->20,FontFamily->"Helvetica",Black,Bold},PlotRange->All, ImageSize->{600},Epilog->{Style[Text["Now",{0,1.4}],24],PointSize[.02],Point[{0, 1}]}];
legend =
  LineLegend[{Black}, {Row[{Subscript[\[Omega], BD],
      "=", \[Omega]BD}]},
   LegendFunction -> (Framed[#, FrameMargins -> 0,
       Background -> White] &),
   LegendLabel ->
    Style["The legend is shown on top", FontFamily -> "Helvetica", 17,
      Blue],
   LabelStyle -> {FontFamily -> "Helvetica", 24, Black, Italic, Bold}];
Legended[Show[pl], Placed[legend, {0, 1}]]
pics = Join[pics, {
Text[Style["Scale factor behavior for BD"], Background->Hue[0.45, 0.5, 1]],
pl
}];
Export["output/BD_plot.png", pl];
Pause[5]

see the result below :

No box legend appears, I have missed something but what ?

UPDATE 2: Here the results with you copy/paste code.

As you can see, only a black big point and the text "Now" appear, no box legend.

UPDATE 3 : the script generates a legend as expected but only Mathematica. Actually, from the beginning, I launch directly the script from command line terminal by doing :

$ wolframscript script_plot.wls

I would be curious to know why it works in Mathematica and not with wolframscript interpreter.

Maybe there is a workaround to get the same figure with wolframscript interpreter ?

Answer 1

Generate some random data

ScaleFactorPast = RandomReal[10, 100];
ScaleFactorFuture = RandomReal[5, 100];

Edit: addressing the comment by the author of the OP

then we do

p1 = ListLinePlot[{ScaleFactorPast, ScaleFactorFuture}, 
   PlotStyle -> {Blue, Blue}, Frame -> True, 
   FrameLabel -> {"t", "a(t)"}, 
   LabelStyle -> {FontSize -> 20, FontFamily -> "Helvetica", Black, 
     Bold}, PlotRange -> All, ImageSize -> {600}];
legend = 
  LineLegend[{Black}, {Row[{Subscript[\[Omega], BD], 
      "=", \[Omega]BD}]}, 
   LegendFunction -> (Framed[#, FrameMargins -> 0, 
       Background -> White] &), 
   LegendLabel -> 
    Style["The legend is shown on top", FontFamily -> "Helvetica", 17,
      Blue], 
   LabelStyle -> {FontFamily -> "Helvetica", 24, Black, Italic, Bold}];
Legended[Show[p1], Placed[legend, {.5, 1.05}]]

To change the position just manipulated the numbers in the Placed command. Example

p1 = ListLinePlot[{ScaleFactorPast, ScaleFactorFuture}, 
   PlotStyle -> {Blue, Blue}, Frame -> True, 
   FrameLabel -> {"t", "a(t)"}, 
   LabelStyle -> {FontSize -> 20, FontFamily -> "Helvetica", Black, 
     Bold}, PlotRange -> All, ImageSize -> {600}];
legend = 
  LineLegend[{Black}, {Row[{Subscript[\[Omega], BD], 
      "=", \[Omega]BD}]}, 
   LegendFunction -> (Framed[#, FrameMargins -> 0, 
       Background -> White] &), 
   LegendLabel -> 
    Style["The legend is shown on top", FontFamily -> "Helvetica", 17,
      Blue], 
   LabelStyle -> {FontFamily -> "Helvetica", 24, Black, Italic, Bold}];
Legended[Show[p1], Placed[legend, {.3, .2}]]

---

Original answer

---

p1 = ListLinePlot[{ScaleFactorPast, ScaleFactorFuture}, 
   PlotStyle -> {Blue, Blue}, Frame -> True, 
   FrameLabel -> {"t", "a(t)"}, 
   LabelStyle -> {FontSize -> 20, FontFamily -> "Helvetica", Black, 
     Bold}, PlotRange -> All, ImageSize -> {600}];
legend = 
  LineLegend[{Black}, {Row[{Subscript[\[Omega], BD], 
      "=", \[Omega]BD}]}, 
   LegendLabel -> 
    Style["The legend is shown on top", FontFamily -> "Helvetica", 17,
      Blue], 
   LabelStyle -> {FontFamily -> "Helvetica", 24, Black, Italic, Bold}];
Legended[Show[p1], Placed[legend, {.5, 1.05}]]

---

Final edit: a screenshot

The code for the screenshot so the author of the OP can copy and paste easily

ScaleFactorPast = RandomReal[10, 100];
ScaleFactorFuture = RandomReal[5, 100];
\[Omega]BD = 9900;
pl = ListLinePlot[{ScaleFactorPast, ScaleFactorFuture}, 
   PlotStyle -> {Blue, Blue}, Frame -> True, 
   FrameLabel -> {"t", "a(t)"}, 
   LabelStyle -> {FontSize -> 20, FontFamily -> "Helvetica", Black, 
     Bold}, PlotRange -> All, ImageSize -> {600}, 
   Epilog -> {Style[Text["Now", {3.1, 1.7}], 24], PointSize[.02], 
     Point[{0, 1}]}];
legend = 
  LineLegend[{Black}, {Row[{Subscript[\[Omega], BD], 
      "=", \[Omega]BD}]}, 
   LegendFunction -> (Framed[#, FrameMargins -> 0, 
       Background -> White] &), 
   LegendLabel -> 
    Style["The legend is shown on top", FontFamily -> "Helvetica", 17,
      Blue], 
   LabelStyle -> {FontFamily -> "Helvetica", 24, Black, Italic, Bold}];
Legended[Show[pl], Placed[legend, {.35, .25}]]

---

Answer 2

You can use the PlotLegends option with relative position syntax of Placed.

With

ωBD = 9900;
baseStyle = {FontSize -> 20, FontFamily -> "Helvetica", Black, Bold};

Then

Plot[x^2
 , {x, 0, 3}
 , PlotLegends ->
  Placed[
   {Style[Row[{Subscript[ω, BD], "=", ωBD}], baseStyle]}
   , {{.05, .95}, {0, 1}}
   ]
 , BaseStyle -> baseStyle
 , Frame -> True
 ]

Placed can take Top, Bottom, and others.

Hope this helps.