How can I predict the asymptotic behavior of a function (not its numerical limit) by simplifying it?

Question

I have a complicated function which I intend to predict its asymptotic behavior (specially I have a $f(r)$ which I want to know its asymptotic behavior in $r\rightarrow \infty$). I know that the command Limit gives me the numerical limit of the function in the special limits instead, I need a function which simulate the behavior of the original function in the limits in the best possible way. Let me get help from a toy example: We know the limit of Sin[x] for x->0 is 0 namely

Limit[Sin[x], x -> 0]
 (*0*)

but we know it behaves just as x function in small xs. The following plot shows this fact:

Plot[{Sin[x], x}, {x, 0, 4}, PlotLegends -> "Expressions"]

So we say x function simulates the asymptotic behavior of Sin[x]. I need to find such a thing for my complicated function. Note that I don't want use fitting or something else, I just want to reach such a function by manipulating (for example choosing terms whit high growth rate and removing other terms) my original function (what was not possible for simple Sin[x] function). Is there any command in Mathematica to do this?

Addendum

This is the closed form of my function:

f[re_] := 
  1/(8 Sqrt[2]
     mp re \[Gamma] (M^2 \[Beta] + mp^2 \[Gamma]) Sqrt[\[Beta] + (
     mp^2 \[Gamma])/M^2]) E^(-2 re^2 \[Gamma]) M^2 norm^2 \[Pi]^(
   3/2) (E^((M \[Alpha] - 2 mp re \[Gamma])^2/(
      2 (M^2 \[Beta] + 
         mp^2 \[Gamma]))) ((-1 + E^((4 M mp re \[Alpha] \[Gamma])/(
           M^2 \[Beta] + mp^2 \[Gamma]))) M \[Alpha] + 
        2 (1 + E^((4 M mp re \[Alpha] \[Gamma])/(
           M^2 \[Beta] + mp^2 \[Gamma]))) mp re \[Gamma]) + 
     E^((M \[Alpha] - 2 mp re \[Gamma])^2/(
      2 (M^2 \[Beta] + mp^2 \[Gamma]))) (M \[Alpha] - 
        2 mp re \[Gamma]) Erf[(M \[Alpha] - 2 mp re \[Gamma])/(
       Sqrt[2] M Sqrt[\[Beta] + (mp^2 \[Gamma])/M^2])] - 
     E^((M \[Alpha] + 2 mp re \[Gamma])^2/(
      2 (M^2 \[Beta] + mp^2 \[Gamma]))) (M \[Alpha] + 
        2 mp re \[Gamma]) Erf[(M \[Alpha] + 2 mp re \[Gamma])/(
       Sqrt[2] M Sqrt[\[Beta] + (mp^2 \[Gamma])/M^2])]);

where all parameters are real and positive. I want to find asymptotic behavior of f[re] when re goes to infinity.

Answer 1

Maybe this:

FullSimplify[
 Series[f[re], {re, Infinity, 1}, 
  Assumptions -> 
   Thread[{γ, M, mp, norm, β, α} > 0]], 
 Thread[{γ, M, mp, norm, β, α} > 0]]

FullSimplify[Normal[%], 
 Thread[{γ, M, mp, norm, β, α} > 0]]
(*
-((E^((M (M α^2 - 
     4 re (mp α + M re β) γ))/(
  2 (M^2 β + mp^2 γ))) M^3 norm^2 π^(
  3/2) (M α - 2 mp re γ))/(
 4 Sqrt[2] mp re γ (M^2 β + mp^2 γ)^(3/2)))
*)

Or, to remove an extra term:

FullSimplify[Normal@Series[%, {re, Infinity, 0}], 
 Thread[{γ, M, mp, norm, β, α} > 0]]
(*
(E^((M (M α^2 - 4 re (mp α + M re β) γ))/(
 2 (M^2 β + mp^2 γ))) M^3 norm^2 π^(
 3/2))/(2 Sqrt[2] (M^2 β + mp^2 γ)^(3/2))
*)

Or to get the same thing:

FullSimplify[
 Asymptotic[f[re], re -> Infinity, 
  Assumptions -> 
   Thread[{γ, M, mp, norm, β, α} > 0], 
  SeriesTermGoal -> 1], 
 Thread[{γ, M, mp, norm, β, α} > 0]]