0
$\begingroup$

Calculating the principal value of the integral in version 13 on Windows 10, I obtain

a = Integrate[Exp[I*s]/(1 + s/(s^2 - 1)^2) - Exp[I*s], {s, -Infinity, Infinity},
PrincipalValue -> True]

2 I \[Pi] ((E^(I Root[1 + # - 2 #^2 + #^4& , 1, 0]) Root[ 1 + # - 2 #^2 + #^4& , 1, 0])/ (1 - 4 Root[1 + # - 2 #^2 + #^4& , 1, 0] + 4 Root[1 + # - 2 #^2 + #^4& , 1, 0]^3) + ( E^(I Root[1 + # - 2 #^2 + #^4& , 2, 0]) Root[ 1 + # - 2 #^2 + #^4& , 2, 0])/ ( 1 - 4 Root[1 + # - 2 #^2 + #^4& , 2, 0] + 4 Root[1 + # - 2 #^2 + #^4& , 2, 0]^3) + ( E^(I Root[1 + # - 2 #^2 + #^4& , 4, 0]) Root[ 1 + # - 2 #^2 + #^4& , 4, 0])/( 1 - 4 Root[1 + # - 2 #^2 + #^4& , 4, 0] + 4 Root[1 + # - 2 #^2 + #^4& , 4, 0]^3)

 N[a]

-1.414 + 0.192275 I

That integral can be treated as the value of the Fourier transform at the unit up to a multiplier Sqrt[2*Pi]:

b=FourierTransform[1/(1 + x/(x^2 - 1)^2) - 1, x, s] // ToRadicals;
N[Sqrt[2*Pi]*b /. s -> 1]

-0.998307 - 0.313707 I

I am sure both calculations apply that formula. Three terms in a confirm it in view of

sol = Solve[1 + s/(s^2 - 1)^2 == 0, s] // ToRadicals;N[sol]

{{s -> -1.49022}, {s -> -0.524889}, {s -> 1.00755 - 0.513116 I}, {s -> 1.00755 + 0.513116 I}}

At least one of the results a and b is not true. I cannot numerically verify these because

NIntegrate[Exp[I*s]/(1 + s/(s^2 - 1)^2) - Exp[I*s], {s, -Infinity,sol[[1, 1, 2]],
sol[[2, 1, 2]], Infinity}, WorkingPrecision -> 40, AccuracyGoal -> 4, PrecisionGoal -> 4]

produces -3.62952953475895858897998849318828745270 + 30.33384783506923620920956921799728322119 I and a warning "NIntegrate::ncvb: NIntegrate failed to converge to prescribed accuracy after 9 recursive bisections in s near {s} = {-1.49021612009995364811638684235445262003720224040232564447871916489713786748684335358978576}. NIntegrate obtained -3.62952953475895858897998849318828745269524061503385359582374023475829095533142179709562225+<<94>> I and 3.12595523476650955449659895306705352885919834467455046353979227028938660290821997839067389`90. for the integral and error estimates."

In a simpler case, both

Integrate[Exp[I*x]/(1 - x^2), {x, -Infinity, Infinity}, PrincipalValue -> True]

and

FullSimplify[Sqrt[2*Pi]*FourierTransform[1/(1 - x^2), x, s] /. s -> 1]

result in \[Pi] Sin[1].

So the question arises: is a or b correct?

$\endgroup$

1 Answer 1

0
$\begingroup$
sol = Solve[1 + s/(s^2 - 1)^2 == 0, s] //ToRadicals; 
(Pi*I*Residue[Exp[I*s]/(1 + s/(s^2 - 1)^2) - Exp[I*s], {s,sol[[1, 1, 2]]}] + 
Pi*I*Residue[Exp[I*s]/(1 + s/(s^2 - 1)^2) - Exp[I*s], {s, sol[[2, 1, 2]]}] + 
2*Pi*I*Residue[Exp[I*s]/(1 + s/(s^2 - 1)^2) - Exp[I*s], {s, sol[[4, 1, 2]]}])//N

-0.998307 - 0.313707 I

confirms b.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.