How to solve a system of differential equations with no exact solution without specifying all of the initial conditions

Question

I have a system of differential equations that does not have an exact solution to them. I get around this by using ndsolvevalue which works great if you provide actual numbers in the initial conditions. However, what I want to do now is leave some variables unspecified so that, upon solving the differential equations, the end result is an equation that is a function of these unspecified variables. I have included the actual code beneath. Basically, I'm trying to solve the system of diff eqs without giving a value to m1 or m2. Is this possible in Mathematica or must the initial conditions have a number attached to them (i.e. are not symbolic in nature)?

G = 6.6743*10^-11;
c = 2.99792458*10^8;
Periods = 5.599829;
P = Periods*86400;
ecc = 0.018;
a = Power[(P^2*G*(m1 + m2))/(4*π^2), (3)^-1]
μ = (m1 m2)/(m1 + m2);
aph = a (1 + ecc);
x0 = (m2*aph)/(m1 + m2)
y0 = 0;
X0 = -((m1*aph)/(m1 + m2))
Y0 = 0;
Vel1 = ((G μ )/a  m2/m1 (1 - ecc)/(1 + ecc) )^(
 1/2)(*initial velocity star 1*)
Vel2 = -((G μ )/a  m2/m1 (1 - ecc)/(1 + ecc) )^(1/2) m1/
  m2(*initial velocity star 2*)


system1 = {
   x1''[t] == -((G m1 m2  (x1[t] - x2[t]))/(
     m1 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/2))),
   y1''[t] == -((G m1 m2  (y1[t] - y2[t]))/(
     m1 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/2))),
   x2''[t] == (G m1 m2  (x1[t] - x2[t]))/(
    m2 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/2)),
   y2''[t] == (G m1 m2  (y1[t] - y2[t]))/(
    m2 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/2))};

initials = {
   x1[0] == x0,
   x1'[0] == 0,
   y1[0] == 0,
   y1'[0] == Vel1,
   x2[0] == X0,
   x2'[0] == 0,
   y2[0] == 0,
   y2'[0] == Vel2};

{xbh1, ybh1, xbh2, ybh2} = 
  DSolve[{system1, initials}, {x1, y1, x2, y2}, t];
bh1 = {(xbh1[t*86400]/(1.5*10^11)), (ybh1[
     t*86400]/(1.5*10^11))};(*larger star position vectors*)
bh2 = {(xbh2[t*86400]/(1.5*10^11)), (ybh2[
     t*86400]/(1.5*10^11))};(*smaller star position vectors*)

Answer 1

I'm trying to solve the system of diff eqs without giving a value to m1 or m2. Is this possible in Mathematica

Use ParametricNDSolve like this

ParametricNDSolve[{system1, initials},{x1[t],y1[t],x2[t],y2[t]},{t,0,1},{m1,m2}]

the end result is an equation that is a function of these unspecified variables"

you can't get an "equation" from numerical solver. Another option other than using ParametricNDSolve is to use Manipulate. Make a slider for m1 and slider for m2. Each time you change the slider, you call NDSolve with the current values for m1 and m2.

Answer 2

From your code we take

G = 6.6743*10^-11;
c = 2.99792458*10^8;
Periods = 5.599829;
P = Periods*86400;
ecc = 0.018;
a = Power[(P^2*G*(m1 + m2))/(4*\[Pi]^2), (3)^-1]
\[Mu] = (m1 m2)/(m1 + m2);
aph = a (1 + ecc);
x0 = (m2*aph)/(m1 + m2)
y0 = 0;
X0 = -((m1*aph)/(m1 + m2))
Y0 = 0;
Vel1 = ((G \[Mu])/a m2/m1 (1 - ecc)/(1 + ecc))^(1/
    2)(*initial velocity star 1*)
Vel2 = -((G \[Mu])/a m2/
       m1 (1 - ecc)/(1 + ecc))^(1/2) m1/m2(*initial velocity star 2*)


system1 = {x1''[
     t] == -((G m1 m2 (x1[t] - 
           x2[t]))/(m1 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/
            2))), y1''[
     t] == -((G m1 m2 (y1[t] - 
           y2[t]))/(m1 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/
            2))), x2''[
     t] == (G m1 m2 (x1[t] - 
         x2[t]))/(m2 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/2)), 
   y2''[t] == (G m1 m2 (y1[t] - 
         y2[t]))/(m2 ((x1[t] - x2[t])^2 + (y1[t] - y2[t])^2)^(3/2))};

initials = {x1[0] == x0, x1'[0] == 0, y1[0] == 0, y1'[0] == Vel1, 
   x2[0] == X0, x2'[0] == 0, y2[0] == 0, y2'[0] == Vel2};

and then we need to use ParametricNDSolve to have some unspecified parameters.

ParametricNDSolve[{system1, initials}, {x1[t], y1[t], x2[t], 
  y2[t]}, {t, 0, 1}, {m1, m2}]

which runs without any issues