How to draw two tangentlines to the circle in the complex plane

Question

From the origin(0,0) of the complex plane, draw two tangent lines to the circle (see plot (p1)).

The absolute value of a complex number is a vector from origin to complex number in complex plane.

p1 = ComplexContourPlot[Abs[z - 6*I] == 3, {z, -10 - 10*I, 10 + 10*I}, GridLines -> Automatic, PlotLabel -> Abs[z - 6*I] == 3]

I do want also show the two axis (Real and Imaginair) in the ComplexContourPlot, but how?

Two values are calculated by : Reduce[{Abs[z - 6*I] == 3, Arg[z] > 0}, z]

Solution: i do have two points, then show this line is a tangent of the circle? Perhaps there is formula for this ? .. or solving with circle math

Note: is there a better approach? using the geometric packages for this.

Answer 1

Not sure how you want to compute tangency, but here's a way that works for the circle:

With[{
  center = 6 I,
  radius = 3,
  z0 = 0
  },
 ComplexContourPlot[
  Abs[z - center] == radius,
  {z, -10 - 10*I, 10 + 10*I},
  GridLines -> Automatic, PlotLabel -> Abs[z - center] == radius,
  Axes -> True, AxesStyle -> Thick,
  Epilog -> {Red, PointSize@Medium,
    {Point[#], InfiniteLine[{ReIm@z0, #}]} & /@
     ReIm@ SolveValues[{Abs[z - center] == radius, 
        Re[(z - center)/(z - z0)] == 0}, z]}]
 ]

Here's another way to compute tangency that works for equations like the one in the OP whose sides are real-valued and defined in terms of a complex z and functions that ComplexExpand will handle:

With[{
  z1 = 6 I,
  f1 = 3,
  z0 = 0,
  a = -5 (1 + I),
  b = 5 (1 + I)
  },
 With[{
   realeqn = Abs[z - z1] - Im[z^3] + 2 Re[z^2] == f1
   },
  ComplexContourPlot[
   realeqn, {z, a, b},
   GridLines -> Automatic, PlotLabel -> realeqn,
   Axes -> True, AxesStyle -> Thick,
   Epilog -> {Red, PointSize@Medium, Point[ReIm@z0], 
     {Point[#], InfiniteLine[{ReIm@z0, #}]} & /@
       ReIm@NSolveValues[
        Append[            (* appends domain restrictions *)
         NestList[         (* {eqn, Dt@eqn} *)
            Dt,
            ComplexExpand[ (* convert to z, Conjugate[z] *)
             realeqn,
             z,
             TargetFunctions -> Conjugate],
            1] /.          (* rewrite Conjugate'[z] *)
           Conjugate'[z] :> Conjugate[Dt[z]]/Dt[z] /.
          {Dt[z] -> (z - z0)}, (* z lies on TL through z0 *)
         Re[a] <= Re[z] <= Re[b] && Im[a] <= Im[z] <= Im[b]
         ],
        z]}]
  ]]

Answer 2

Let us call the parametric description of the circle:

circ[ph_] := 6 I + 3 Exp[I ph]

The derivative of circ is a tangent Further, the line from the origine to the circle point, where the tangent touches, is a multiple of the derivative.

Therefore, a circle-tangent point plus a multiple of the tangent must give the origin (0). We may then write:

circ'[ph] lam + circ[ph] == 0

Note further that lam and ph are real and we solve:

Reduce[{circ'[ph] lam + circ[ph] == 0, {  ph, lam} \[Element] 
   Reals}, { ph, lam}]

The information: ph= -Pi 5/6 and -Pi/6 is all we need to draw a graphics:

ParametricPlot[ReIm[circ[ph]], {ph, 0, 2 Pi}, 
 Epilog -> {Line[{{0, 0}, ReIm[circ[-Pi 5/6]]}], 
   Line[{{0, 0}, ReIm@circ[-Pi/6]}], 
   Point[{ReIm@circ[-Pi 5/6], ReIm@circ[-Pi/6]}]}, 
 PlotRange -> {{-3, 3}, {0, 9}}]