1
$\begingroup$

When a==a,

Clear["Global`*"];
c[t_] := {a*Cos[t], a*Sin[t]};
vf = {y^2, 0};
Integrate[vf.Dt[{x, y}, t] /. Thread[{x, y} -> c[t]], {t, 0, Pi},Assumptions-> a>0]

(* Integrate returns unevaluated. *)

When a==2, I can get the result.

Clear["Global`*"];
c[t_] := {2*Cos[t], 2*Sin[t]};
vf = {y^2, 0};
Integrate[vf.Dt[{x, y}, t] /. Thread[{x, y} -> c[t]], {t, 0, Pi}]

(*-(32/3)*)
$\endgroup$

1 Answer 1

6
$\begingroup$
  • Mathematica not easy to handle differential form. Here we use traditional form.
c[t_] = {a*Cos[t], a*Sin[t]};
vf = {y^2, 0};
Integrate[c'[t] . vf /. Thread[{x, y} -> c[t]], {t, 0, Pi}]

-((4 a^3)/3)

  • Another way is set Constants -> {a} in Dt.
c[t_] := {a*Cos[t], a*Sin[t]};
vf = {y^2, 0};
Integrate[
 vf . Dt[{x, y}, t, Constants -> {a}] /. Thread[{x, y} -> c[t]], {t, 
  0, Pi}, Assumptions -> a > 0]

-((4 a^3)/3)

$\endgroup$
1
  • $\begingroup$ The answer is great. Thanks a lot!! @cvgmt $\endgroup$
    – lotus2019
    Mar 4, 2022 at 6:11

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.