How would I find the Binormal vector? [duplicate]

How would I find the Binormal vector if r[t_]:={sin(7t),t^4,cos(7t)} in Mathematica?

This is the Mathematica code I have:

    r[t_] := {Sin[7 t], t^4, Cos[7 t]};
circle :=
ParametricPlot3D[r[t], {t, 0, 2 Pi/7}, PlotStyle -> {Thick,
Black}]
utvec[t_] := {r'[t]/sqrt[r'[t].r'[t]]}
utvec[0.4]
(r'[0.4])*t + r[0.4]
Show[circle,
ParametricPlot3D[(r'[0.4])*t + r[0.4], {t, 0, 2 Pi/7},
PlotStyle -> {Thick, Blue}]]
nvec[t_] := {r''[t]/sqrt[r''[t].r''[t]]}
nvec[0.4]
(r''[0.4])*t + r[0.4]
ubnvec[t_] := Cross[utvec[t], nvec[t]]


Also, how can I graph something that looks like this:

• Welcome to Mathematica SE. To get started:1) take the introductory tour now,2) when you see good questions and answers, vote them up by clicking the gray triangles, because the credibility of the system is based on the reputation gained by users sharing their knowledge,3) remember to accept the answer, if any, that solves your problem, by clicking checkmark sign,4) give help too, by answering questions in your areas of expertise.
– user49048
Commented Mar 4, 2022 at 2:46
• Please post the Mathematica code. Please see FrenetSerretSystem Commented Mar 4, 2022 at 2:48
• Please, also, fix your sytnax properly. It should be r[t_] := {Sin[7 t], t^4, Cos[7 t]}
– user49048
Commented Mar 4, 2022 at 2:48
• That's exactly what I needed, thanks. Commented Mar 4, 2022 at 5:28

We have

r[t_] := {Sin[7 t], t^4, Cos[7 t]}


Now, we can implement directly the definition of the binormal vector

FullSimplify[Cross[r'[t], r''[t]]/Norm[Cross[r'[t], r''[t]]]]


which gives

{(4 t^2 (-7 t Cos[7 t] + 3 Sin[7 t]))/Sqrt[ 2401 + 16 Abs[t^2 (-7 t Cos[7 t] + 3 Sin[7 t])]^2 + 16 Abs[t^2 (3 Cos[7 t] + 7 t Sin[7 t])]^2], 49/Sqrt[ 2401 + 16 Abs[t^2 (-7 t Cos[7 t] + 3 Sin[7 t])]^2 + 16 Abs[t^2 (3 Cos[7 t] + 7 t Sin[7 t])]^2], ( 4 t^2 (3 Cos[7 t] + 7 t Sin[7 t]))/Sqrt[ 2401 + 16 Abs[t^2 (-7 t Cos[7 t] + 3 Sin[7 t])]^2 + 16 Abs[t^2 (3 Cos[7 t] + 7 t Sin[7 t])]^2]}

In case that t is real, we can inform Mathematica about that fact as follows:

FullSimplify[Cross[r'[t], r''[t]]/Norm[Cross[r'[t], r''[t]]],
t ∈ Reals]


which results in

{(4 t^2 (-7 t Cos[7 t] + 3 Sin[7 t]))/Sqrt[
2401 + 144 t^4 + 784 t^6], 49/Sqrt[2401 + 144 t^4 + 784 t^6], (
4 t^2 (3 Cos[7 t] + 7 t Sin[7 t]))/Sqrt[2401 + 144 t^4 + 784 t^6]}

r[t_] = {Sin[7 t], t^4, Cos[7 t]};
{tangent, normal, binormal} = FrenetSerretSystem[r[t], t][[2]];
t = 1;
Show[ParametricPlot3D[r[t], {t, 0, 2 Pi/5}, PlotStyle -> Yellow],
Graphics3D[{AbsoluteThickness[5], White,
Arrow[{r[t], r[t] + tangent}], Blue, Arrow[{r[t], r[t] + normal}],
Red, Arrow[{r[t], r[t] + binormal}]}], Background -> Cyan,
PlotRange -> All, Boxed -> False, Axes -> False,
ViewPoint -> {1.20, 2.86, -1.31},
ViewVertical -> {0.25, 0.96, -0.04}]


• (+1) nice use of the FrenetSerretSystem for these purposes!
– user49048
Commented Mar 4, 2022 at 4:01
• (+1) Thank you :) Commented Mar 4, 2022 at 4:05