1
$\begingroup$

enter image description hereIm trying to find the exact solution for the singular BVP $y^{\prime\prime}(t)=-\frac{2}{t}y^{\prime}(t)+y^{5}(t)$ with the Boundary Conditions $y(1)=\sqrt{\frac{3}{4}}$ and $y^{\prime}(0)=0$ and $0<t<1$. I know that the exact solution of this equation is $y(t)=\sqrt{\frac{3}{3+t^2}}$. Now I want to find the exact solution using mathemtica software. I tried the following first: (1)

DSolve[{y''[t] == -(2/t) (y'[t]) + (y[t])^5, y[1] == Sqrt[3/4], y'[0] == 0}, y[t], t]

but I cant find the exact solution like above. After this, I tried

SOL = DSolve[{y''[t] == -(2/t) (y'[t]) + (y[t])^5}, y[t],  t] (* General solution *)
F = FindRoot[{(y[t] /. SOL[[1]] /. t -> 1 /. C[1] -> c1 /.C[2] -> c2) ==Sqrt[3/4], (y'[t] /. SOL[[1]] /. t -> 0 /. C[1] -> c1 /.C[2] -> c2) == 0}, {c1, 1/2}, {c2, 1/2}] // Chop // Rationalize
(* Finding constans c1 and c2 *)
SOL /. C[1] -> c1 /.C[2] -> c2 /. F(* Paste constants c1 and c2 to general solution *)
(*{{y[t]\->Sqrt(3/(3+t)^2)}*)

In this case, I also failed to find the exact solution. Please help me any one. Advance thanks.

$\endgroup$
19
  • 4
    $\begingroup$ Second comment: you said that you know the analytic solution and you gave a function. Even when Mathematica cannot get the answer from DSolve it is able to verify it when we impose it. In this case, it does not. If you run y''[t] == -(2/t) (y'[t]) + (y[t])^5 /. y -> (Sqrt[3/(3 + #^2)] &) // FullSimplify you will see that it does not yield True. Could you please check the solution you provided for the y[t]? $\endgroup$
    – user49048
    Feb 23, 2022 at 20:47
  • 4
    $\begingroup$ The main problem is that "your exact solution" does not satisfy the original equation. I can say that you haven't checked if this is a solution $\endgroup$
    – Artes
    Feb 24, 2022 at 5:07
  • 2
    $\begingroup$ Given that exact solution, your equation is wrong. You need a negative sign before y[t]^5. Here is why: If you differentiate \sqrt{3} \sqrt{\frac{1}{t^2+3}} once, you get -\sqrt{3} t \left(\frac{1}{t^2+3}\right)^{3/2}. If you differentiate twice, you get \sqrt{3} \left(\frac{1}{t^2+3}\right)^{5/2} \left(2 t^2-3\right). Now the closest form you can get it in the main equation: after multiplying the first derivative to (2/t) and dividing by y[t]^5 you will get -1. And yes, Mathematica can't solve this by normal DSolve without other advanced techniques that I am not aware of. $\endgroup$
    – MathX
    Feb 24, 2022 at 16:04
  • 3
    $\begingroup$ First No way to find exact solution by Mathematica. Second give us exact solution of this equation, a sceenshot from article(I do not have 42.99 euros), because as has been mentioned many times, your exact solution does not satisfy the original equation. $\endgroup$ Feb 24, 2022 at 17:51
  • 3
    $\begingroup$ The Singh and Kumar reference confirms Mariusz's claim above that the equation is $u''+2/x u'=u^5$: See reference (no euros needed): sciencedirect.com/science/article/abs/pii/… $\endgroup$
    – josh
    Feb 24, 2022 at 19:51

1 Answer 1

2
$\begingroup$

Using perturbation method for the equation:

$$y''(x)+\frac{2 y'(x)}{x}+y(x)^5=0$$

If solution is y[x]=Sqrt[3/(3 + x^2)] for x=0 is: 1.

Then we have initial conditions:y[0]=1,and y'[0]=0

ClearAll["`*"]; Remove["`*"]

eq = y''[x] + 2/x*y'[x] + \[Delta]*y[x]^5;

(*Perturbation method*)

ord = 10;
eqs = CoefficientList[
Normal[Series[
 eq /. y -> 
   Function[x, 
    Evaluate[Sum[y[i][x] \[Delta]^i, {i, 0, ord}]]], {\[Delta], 0,
   ord}]], \[Delta]];yiList = {};
 Do[AppendTo[yiList, 
MapAt[Factor, 
DSolve[{(eqs[[k + 1]] /. yiList /. Log[Exp[x]] -> x) == 0, 
   y[k][0] == If[k == 0, 1, 0], y[k]'[0] == If[k == 0, 0, 0]}, 
  y[k][x], x][[1, 1]], 2]], {k, 0, ord - 2}];

(*Series solution:*)

sol2 = Sum[y[i][x] \[Delta]^i, {i, 0, ord - 2}] /. yiList /. \[Delta] -> 1

(*Converting series solution to function:*) 

FullSimplify[FindGeneratingFunction[
Table[SeriesCoefficient[sol2 + O[x]^18, n], {n, 0, 10}], x], 
Assumptions -> x > 0]

(*Sqrt[3]/Sqrt[3 + x^2]*)

With this metod we can solve:$$y''(x)+\frac{2 y'(x)}{x}-y(x)^5=0$$ with: y[0]=1,and y'[0]=0.

Exact solution is:$$y(x)=\frac{1}{\sqrt{1-\frac{x^2}{3}}}$$

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.