1
$\begingroup$

If

$$x=\ln\left|y+\sqrt{y^{2}+1}\right|$$

Is there a way to obtain $y$ in terms of $x$ in Mathematica?

How to find dx/dy in Mathematica? I tried: D[x,y] in mathematica. But the answer I got is:

$$\frac{sgn\left(\phi+\sqrt{\phi^{2}+1}\right)\left|\phi+\sqrt{\phi^{2}+1}\right|'}{\sqrt{\phi^{2}+1}}$$

Why there is a $'$ in the the modulus again. I think it means we need to find derivative again.

$\endgroup$

2 Answers 2

4
$\begingroup$
Clear["Global`*"]

x = Log[Abs[y + Sqrt[y^2 + 1]]];

If y is real then

Assuming[Element[y, Reals], D[x, y] // FullSimplify]

(* 1/Sqrt[1 + y^2] *)

or

D[x /. Abs[z_] :> Sqrt[z^2], y] // Simplify

(* 1/Sqrt[1 + y^2] *)

or

D[x /. Abs :> RealAbs, y] // Simplify

(* 1/Sqrt[1 + y^2] *)

% === %% === %%%

(* True *)

EDIT: To obtain y in terms of x

Clear["Global`*"]

eqn = x == Log[Abs[y + Sqrt[y^2 + 1]]];

sol = Solve[eqn, y, Reals]

(* {{y -> 1/2 E^-x (-1 + E^(2 x))}} *)

% // FullSimplify

(* {{y -> Sinh[x]}} *)

eqn /. sol[[1]] // Simplify[#, Element[x, Reals]] &

(* True *)
$\endgroup$
6
$\begingroup$

As a function of a complex argument Abs is not differentiable. E.g. for z=x+I y:

(Abs[z0+dx]-Abs[0])/dx -> 1
(Abs[z0+I dy]-Abs[0])/(I dy) -> - I

Therefore, the limit depends on the direction. However, if you restrict the argument to be real, then you can use FullSimplify to get the derivative of Abs:

FullSimplify[D[Abs[x], x], x \[Element] Reals]
(* Sign[x] *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.