I have a number representing date (yyyymmdd):
19001231
I want to convert this number to
{1900,12,31}
How to do this? There should be easy answer.
$\begingroup$
$\endgroup$
Add a comment
|
11 Answers
$\begingroup$
$\endgroup$
2
You can also use NumberDecompose with the basis {10000, 100, 1}:
NumberDecompose[19001231, 10^{4, 2, 0}]
{1900, 12, 31}
-
3$\begingroup$ (+1). I did not even know about
NumberDecompose$\endgroup$– user49048Commented Feb 14, 2022 at 4:01 -
1$\begingroup$ This looks the most elegant way! $\endgroup$ Commented Feb 14, 2022 at 4:04
$\begingroup$
$\endgroup$
DateList[{IntegerString @ #, {"Year", "", "Month", "", "Day"}}][[;; 3]] & @ 19001231
{1900, 12, 31}
DateObject[{IntegerString@#, {"Year", "", "Month", "", "Day"}}] & @ 19001231
$\begingroup$
$\endgroup$
1
Since the year is fixed 4 digits, and day and month are fixed 2 digits, one way is to do
n=19001231;
m=IntegerDigits[n];
FromDigits[#]&/@{m[[1;;4]],m[[5;;6]],m[[7;;8]]}
There might be a build in function that does this already related to date/time formatting. I have not looked.
-
2$\begingroup$ +1 Note that the last line can be written more succinctly as
FromDigits /@ {m[[;; 4]], m[[5 ;; 6]], m[[7 ;;]]}$\endgroup$ Commented Feb 14, 2022 at 3:41
$\begingroup$
$\endgroup$
Yet another one-liner: FoldPairList + QuotientRemainder:
FoldPairList[QuotientRemainder, 19001231, 10^{4, 2, 0}]
{1900, 12, 31}
$\begingroup$
$\endgroup$
$\begingroup$
$\endgroup$
2
Interpret the string as a "Date".
Interpreter["Date"]["19001231"][#] & /@ {"Year", "Month", "Day"}
{1900, 12, 31}
EDIT
I should have said: convert the number to string; interpret the string as a date and then extract parts (to answer the question as posed and also to avoid repeating the caculations).
str = IntegerString@19001112
dobj = Interpreter["Date"][str]
{y, m, d} = dobj[#] & /@ {"Year", "Month", "Day"}
Interpreter is slow, but it is a built-in function designed for the purpose.
-
2$\begingroup$ Thank you for letting me know such a nice built-in function. $\endgroup$ Commented Feb 14, 2022 at 6:57
-
3$\begingroup$
f[#]&/@ ...could be written asf/@...$\endgroup$ Commented Feb 14, 2022 at 17:31
$\begingroup$
$\endgroup$
Processing dates by integers is extremely error-prone. Here is an example from the excellent book by Paul Wellin (p.598).
Compare this
DateList[19001231];
Take[%,3]
(* Out: {1900, 8, 8} *)
with this
DateList[ToString[19001231]]
Take[%, 3]
(* Out: {1900, 12, 31} *)
$\begingroup$
$\endgroup$
3
Similar to the response by @Nasser
MapAt[FromDigits,
TakeList[IntegerDigits[19001231], {4, 2, 2}], {{1}, {2}, {3}}]
which yields
{1900, 12, 31}
-
2$\begingroup$ (+1) Alternatively
FromDigits/@TakeList[IntegerDigits[19001231],{4,2,2}](which I was going to post!) $\endgroup$– user1066Commented Feb 14, 2022 at 3:41 -
$\begingroup$ Also very nice, indeed! $\endgroup$– user49048Commented Feb 14, 2022 at 3:45
-
$\begingroup$
$\endgroup$
An option using the Date functionality:
DateValue[#, {"Year", "Month", "Day"}] &@DateObject@ToString@19001231
answered Sep 20, 2022 at 15:41
$\begingroup$
$\endgroup$
ToExpression @* StringJoin /@
TakeList[Characters @ ToString[19001231], {4, 2, 2}]
{1900, 12, 31}
$\begingroup$
$\endgroup$
2
Using DateString and StringSplit:
dstr = DateString[ToString@19001231, "ISODate"]
"1900-12-31"
ToExpression@StringSplit[dstr, Except[DigitCharacter]]
{1900, 12, 31}
The shortest form (Thanks to @eldo!):
StringSplit[DateString[19001231, "ISODate"], "-"]
answered Mar 18 at 17:35
-
1$\begingroup$ Very nice! Could be shortened to
StringSplit[DateString[19001231, "ISODate"], "-"]$\endgroup$– eldoCommented Mar 18 at 17:47 -
$\begingroup$ Thanks, @eldo! Let me add the shortest path you suggest ;) $\endgroup$ Commented Mar 18 at 17:49