How to force Animate to work properly?

Question

I would like to animate a simple clip where the points appear at a plot

LIN = {};
Animate[Poin1 = RandomVariate[UniformDistribution[{{0, 1}, {0, 1}}]]; 
 LIN = Append[LIN, {Poin1}];
 TableForm[{{n}, ListPlot[LIN, ImageSize -> 500, PlotStyle -> Red] }], {n, 1, 5, 
  1}, AnimationRepetitions -> 1, AnimationRate -> .5 , 
 DisplayAllSteps -> True]

The code should result in the plot with increasing number of points, from 1 to 5. At the end, the plot should have 5 static points. But in fact, the points are being added in a continuous manner.

When I stop the animation at t=2, the points continue to appear. This looks like the animation works in a non-stop mode

Answer 1

Clear["Global`*"]

LIN = RandomVariate[UniformDistribution[{{0, 1}, {0, 1}}], 5];

Animate[
 ListPlot[LIN[[;; n]],
  PlotRange -> {{0, 1}, {0, 1}},
  PlotRangePadding -> Scaled[.05],
  ImageSize -> Medium,
  PlotStyle -> Red],
 {n, 1, 5, 1},
 AnimationRepetitions -> 1,
 AnimationRate -> .5,
 DisplayAllSteps -> True]

Answer 2

The points are adding up because you do nowheer reset LIN to an empty list.

Clear["Global`*"]
LIN = {};

fun = Function[{m}, If[m == 1, LIN = {}];
  AppendTo[LIN, RandomVariate[UniformDistribution[{{0, 1}, {0, 1}}]]]]

Animate[
  ListPlot[fun[n], ImageSize -> 500, PlotStyle -> Red]
 , {n, 1, 5, 1}, AnimationRepetitions -> 1, AnimationRate -> .5]

You will see that the animation does not exactly stop after 1 iteraion. It makes some additional steps. Why that is, I do not know.