Exporting equations from Mathematica to Corel with full Latex quality

Question

I am wondering if there is any possible solution to exporting equations from Mathematica to Corel. I was trying first to export an equation as pdf from Mathematica and then to import .pdf to Corel, but many characters are missed. Maybe someone had success with this kind of problem.

Answer 1

There is a similar problem with Adobe Illustrator, too. For that purpose, I use the following function (see my web site for more info):

toPDF[x_, opts : OptionsPattern[]] := 
  If[! ImageQ[x], 
   First@ImportString[
     ExportString[
      Pane[Style[TraditionalForm[HoldForm[x]], 
        FilterRules[{opts}, Options[Style]]], 
       FilterRules[{opts}, ImageSize], 
       BaseStyle -> {FontFamily -> "Times New Roman", 
         Background -> (Background /. {opts} /. {Background -> 
              None})}], "PDF"], "PDF", "TextMode" -> "Outlines"]];
SetAttributes[toPDF, HoldFirst]

Example:

toPDF[Integrate[1 + Sin[x]^2, {x, 0, Pi}], FontSize -> 18]

Now you can either highlight the result (as I did above) and copy it as PDF (on Mac), or type Export["eq.pdf", %] in the next cell, to save to a file.

The reason I added the attribute HoldAll above is that I wanted to be able to export expressions like integrals without having them be evaluated. So the purpose of this function is really geared toward typesetting equations, and then copying them to Illustrator. Maybe this is also what you want for your drawing application.

I use Pane as a wrapper for the equation in order to be able to control the bounding box of the PDF. The function also accepts a Background option in case you want to add a color behind the equation.

Edit for version 10.1:

Due to added bugs in Import with PDF format, the example above won't work properly anymore. Another solution that still does work is the function gsExport from my answer here. You have to make sure that ghostscript is installed and in the search path. If the linked code doesn't find your gs command, you could add the path directly in the code, as in /path/to/gs. After invoking gsExport["filename.pdf", HoldForm[Integrate[1 + Sin[x]^2, {x, 0, Pi}]]], you can do Import["filename.pdf"].