3
$\begingroup$

How to prove that the following integral assuming $k^2 < 1$ $$\int_{0}^{1} \frac{d x}{\sqrt{1-x^2}\sqrt{1-k^2 x^2}}$$ is convergent?

Assuming[k^2 < 1, 
 Integrate[1/Sqrt[(1 - x^2)*(1 - k^2*x^2)], {x, 0, 1}]]
EllipticK[k^2]
FunctionRange[{EllipticK[k^2], 0 <= k^2 < 1}, k, y, Reals]

y >= Pi/2

It can also be expressed as how to prove convergence of the following elliptic integral?

EllipticK[k^2], (k^2<1)
$\endgroup$
3
  • $\begingroup$ Integrate[1/Sqrt[(1 - x^2)*(1 - k^2*x^2)], {x, 0, 1}] $\endgroup$
    – cvgmt
    Jan 31, 2022 at 2:20
  • $\begingroup$ FunctionDomain[EllipticK[k^2], k] $\endgroup$
    – cvgmt
    Jan 31, 2022 at 2:21
  • $\begingroup$ It is convergent because there is only one singularity on the path, at the endpoint x=1, and it is easuly seen to be integrable by series expansion: In[188]:= Series[1/Sqrt[(1 - x^2) (1 - k^2 x^2)], {x, 1, 1}, Assumptions -> -1 < k < 1] Out[188]= SeriesData[x, 1, { 2^Rational[-1, 2] (1 - k^2)^Rational[-1, 2] (1 - x)^Rational[-1, 2], Rational[-1, 4] 2^Rational[-1, 2] ( 1 - k^2)^Rational[-1, 2] (-1 + k^2)^(-1) (-1 + 5 k^2) ( 1 - x)^Rational[-1, 2]}, 0, 2, 1] $\endgroup$ Jan 31, 2022 at 14:08

2 Answers 2

8
$\begingroup$

In fact the original question asks for demonstrating that the following integral is finite, what Matematica can do simply

FullSimplify[ Integrate[1/(Sqrt[1 - x^2] Sqrt[1 - k^2 x^2]), {x, 0, 1}]  
              < Infinity,
             -1 < k < 1 ]

True

A mathematical proof is comparably easy. We can see that for $\; -1< k<1$ and $\;0\leq x <1$ we have $\frac{1}{ \sqrt{1-k^2 x^2}} \leq \frac{1}{\sqrt{1-k^2}}\;$ and so $$\frac{1}{\sqrt{1-x^2} \sqrt{1-k^2 x^2}} \leq \frac{1}{\sqrt{1-k^2}\sqrt{1-x^2}}$$ and since the both sides of this inequality are nonnegative, integration is a generalization of summation we get $$\int_{0}^{1}\frac{dx}{\sqrt{1-x^2} \sqrt{1-k^2 x^2}} \leq \int_{0}^{1}\frac{dx}{\sqrt{1-k^2}\sqrt{1-x^2}} =\frac{\pi}{2\sqrt{1-k^2}}$$ recalling that $\int_{0}^{1}\frac{dx}{\sqrt{1-x^2}}=\frac{\pi}{2}$

Q.E.D.

A counterpart of a crucial step in the proof can be demonstrated simply as well

Simplify[ 1/(Sqrt[1 - x^2] Sqrt[1 - k^2 x^2]) 
          <= 1/(Sqrt[1 - x^2] Sqrt[1 - k^2]), 
                      -1 < k < 1 && 0 <= x < 1]

True

We've got a better upper bound for the complete elliptic integral of the first kind namely $\frac{\pi}{2 \sqrt{1-k^2}}$. Analogously we can find lower bound of the form $\frac{\pi \arcsin(k)}{2 k}$ and in a slightly different way another lower bound $\frac{\log(\frac{1-k}{1+k})}{2 k}$. The first one works for $x$ close to $0$ and the other one for $x$ close to $1$.

We show all the graphs of appropriate functions on the following plot

Plot[{ EllipticK[k^2], Pi/(2 Sqrt[1 - k^2]), Pi/2 (ArcSin[k]/k), 
      Log[(1 + k)/(1 - k)]/(2 k)}, {k, 0, 1}, 
  PlotStyle -> {Thick, Dashed, Dashed, Dashed}, AxesOrigin -> {0, 0}, 
  PlotLegends -> "Expressions", PlotRange -> {0, 5}]

enter image description here

$\endgroup$
1
  • 1
    $\begingroup$ Thank you very much! $\endgroup$
    – lotus2019
    Feb 1, 2022 at 2:46
1
$\begingroup$
Integrate[1/Sqrt[(1 - x^2)*(1 - k^2*x^2)], {x, 0, 1}]

ConditionalExpression[EllipticK[k^2], Re[k^2] <= 1 || k^2 ∉ Reals]

FunctionDomain[EllipticK[k^2], k]

-1 < k < 1

The definition domain just indicated that the EllipticK[k^2] converge only in -1 < k < 1 and divergence outside such interval.

$\endgroup$
4
  • $\begingroup$ That is not so simple in view of FunctionDomain[EllipticK[k^2], k, Complexes] resulting in -1 + k^2 != 0. It's unclear to me whether the integral Integrate[1/Sqrt[(1 - x^2)*(1 - k^2*x^2)], {x, 0, 1}] converges for such values of k. $\endgroup$
    – user64494
    Jan 31, 2022 at 8:33
  • $\begingroup$ ClearAll[k]; Integrate[1/Sqrt[(1 - x^2)*(1 - k^2*x^2)], {x, 0, 1}, Assumptions -> k \[Element] Reals && (k^2 > 1 || k^2 < -1)] outputs (-I EllipticK[1 - 1/k^2] + EllipticK[1/k^2])/Abs[k]. $\endgroup$
    – user64494
    Jan 31, 2022 at 9:59
  • $\begingroup$ Thank you!@cvgmt@user64494 $\endgroup$
    – lotus2019
    Feb 1, 2022 at 2:48
  • $\begingroup$ EllipticK[k^2] does converge for $k>1$ contrary to your statment: "only in -1 < k < 1 and ..." $\endgroup$
    – Artes
    Feb 24, 2023 at 11:46

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.