Series expansion not returning anything

Question

I have a differential equation, which I want to expand as a series at a finite $r$ value - the horizon, and at $\infty$. The functions involved are definitely cumbersome, and I have recreated my code below:

f[r_] := (r/rs)^(2 e) (((1 - (rs/r)^(1 + e)) (2 + e + e (rs/r)^(1 + e))^2)/(16 (1 + e)^4 (1 + d^2L^2 g0^2 rs^2/(16 r^4)))) ((2 + e)^2 -e^2 (rs/r)^(1 +e));
g[r_] := (((r/rs)^(1 + e) - 1) ((r/rs)^(1 +e) (2 + e)^2 - e^2))/((1 + d^2 L^2 g0^2 rs^2/(16 r^4))((e + (r/rs)^(1 + e) (2 + e))^2)) // Simplify ;
h[r_] := r^2 (1 + d^2 L^2 g0^2 rs^2/(16 r^4));
k[r_] := Sqrt[g[r]/f[r]] h[r] // FullSimplify;
\[CapitalDelta]2[r_] := g[r] h[r] + a^2 // FullSimplify;

Here, d,g0,e,rs are all constants. I want to solve the resulting differential equations, for different values of these parameters. Consider the following sample values.

e = 0.01;
d = 0;
rs = 2 M;
L = 0;
g0 = 0;

The actual equation is defined as follows:

$Assumptions = {M > 0, a > 0, r > 0, a < M, w > 0};
rplus = M + Sqrt[M^2 - a^2];
rminus = M - Sqrt[M^2 - a^2];
f2[r_] := \[CapitalDelta]2[r]/(k[r] + a^2) // Simplify;
Gaos[r_] := (k'[r] \[CapitalDelta]2[r])/(2 (k[r] + a^2)^2) // FullSimplify
KKaos = (k[r] + a^2) \[Omega] - a m // Simplify;

Vaos = (KKaos^2 - \[CapitalDelta]2[r] \[Lambda])/(k[r] + a^2)^2 - Gaos[r]^2 - f2[r] Gaos'[r] // Simplify;

eqnaos = f2[r]^2 R''[r] + f2'[r] f2[r] R'[r] + Vaos R[r] ;

For one thing, I am unable to even Simplify the potential Vaos or the equation eqnaos. After running the Simplify command for a long time, I get an error that asks me to increase the TimeConstraint. But when I do this, I either get the same error again, or the kernel just restarts.

The actual series expansion I want to perform is given below:

R[r_] := (r - rplus)^AA h2[r];
eqn1aos = eqnaos/(r - rplus)^AA;
ruleHaosold = {AA -> (I (a m - 2 M (M + Sqrt[-a^2 + M^2]) w))/(2 Sqrt[-a^2 + M^2])};
ORDH = 3;
ssaos = Series[eqn1aos //. ruleHaosold, {r, rplus, ORDH}];

The last series expansion keeps running, and I get no output and no error. I have tried running this overnight as well.

If I set e = 0 the entire set of functions and the equation simplifies greatly (and is a known simpler case of the problem I'm trying to solve) and the series expansion and the rest of my code works perfectly.

I also have a similar series expansion at $\infty$ which also suffers from the same problem where it just keeps running indefinitely. How do I fix this?

Answer 1

Don't define rplus at the beginning, but after Series taken. Otherwise it is too complex for Series.

$Assumptions = {M > 0, a > 0, r > 0, a < M, w > 0};

(*   rplus=M+Sqrt[M^2-a^2];
     rminus=M-Sqrt[M^2-a^2];   *)

f2[r_] = \[CapitalDelta]2[r]/(k[r] + a^2) // Simplify;
Gaos[r_] = (k'[r] \[CapitalDelta]2[r])/(2 (k[r] + a^2)^2) // 
Together // Simplify;
KKaos = (k[r] + a^2) \[Omega] - a m // Together // Simplify;
Vaos = (KKaos^2 - \[CapitalDelta]2[r] \[Lambda])/(k[r] + a^2)^2 - 
 Gaos[r]^2 - f2[r] Gaos'[r] // Together // Simplify;
eqnaos = f2[r]^2 R''[r] + f2'[r] f2[r] R'[r] + Vaos R[r] //  Together //
Simplify;


R[r_] = (r - rplus)^AA h2[r]
eqn1aos = eqnaos/(r - rplus)^AA // Together // Simplify
ruleHaosold = {AA -> (I (a m - 
      2 M (M + Sqrt[-a^2 + M^2]) w))/(2 Sqrt[-a^2 + M^2])} // 
Together // Simplify
ORDH = 3;

ssaos = Series[eqn1aos //. ruleHaosold, {r, rplus, ORDH}]

Normal[ssaos] /. rplus -> M + Sqrt[M^2 - a^2]