How can I fill the inverted region of this?

Question

How can I fill the inverted region of this? I want to fill the region outside of this shape t instead.

ListLinePlot[{{-1, 1}, {1, 1}, {10,
10}, {10, -10}, {1, -1}, {-1, -1}, {-10, -10}, {-10, 10}, {-1, 1}},
PlotStyle -> Directive[Red, Dashed, Thickness[0.008]],
Filling -> {1 -> Axis}, FillingStyle -> Lighter[Gray, 0.85]]

Answer 1

pts = {{-1, 1}, {1, 1}, {10, 
   10}, {10, -10}, {1, -1}, {-1, -1}, {-10, -10}, {-10, 10}, {-1, 1}}

Using Prolog:

ListLinePlot[pts, PlotStyle -> Directive[Red, Dashed, Thickness[0.008]]
 , Filling -> {1 -> Axis}, FillingStyle -> Lighter[White, 0.85]
 , Prolog -> {GrayLevel[0.9]
   (*, Rectangle[{-10,-10},{10,10}]*)
   , Rectangle @@ {
       {
        Min[#[[All, 1]]], Min[#[[All, 2]]]}
       , {Max[#[[All, 1]]], Max[#[[All, 2]]]
        }
       } &@pts
   }
 ]

Answer 2

• Use RegionDifference to construct the outer region.

pts = {{-1, 1}, {1, 1}, {10, 
    10}, {10, -10}, {1, -1}, {-1, -1}, {-10, -10}, {-10, 10}, {-1, 1}};
outreg = TransformedRegion[Rectangle @@ CoordinateBoundingBox[pts], 
   ScalingTransform[{1.2, 1.2}, Mean[pts]]];
inreg = Polygon[pts];
clip = RegionDifference[outreg, inreg];
Graphics[{{Lighter[Gray, 0.5], 
   clip}, {EdgeForm[Directive[Red, Dashed, Thickness[0.008]]], 
   FaceForm[], inreg}}, AspectRatio -> 1/GoldenRatio, Axes -> True]

• Use Polygon[outpts -> {inpts}] to get holes.

pts = {{9, 11}, {11, 11}, {20, 15}, {9, -5}, {11, 9}, {9, 9}, {-10, 
    0}, {0, 20}, {9, 11}};
inpts = Most@pts;
{{xmin, xmax}, {ymin, ymax}} = {MinMax[pts[[;; , 1]]], 
   MinMax[pts[[;; , 2]]]};
outpts = {{xmin, ymin}, {xmax, ymin}, {xmax, ymax}, {xmin, ymax}};
clip = Polygon[outpts -> {inpts}];
Graphics[{Lighter[Gray, 0.5], clip, 
  Directive[Red, Dashed, Thickness[0.008]], Line[pts]}, 
 AspectRatio -> 1/GoldenRatio, Axes -> True, PlotRangePadding -> .8]

Answer 3

Fill with white and make the background gray:

ListLinePlot[{{-1, 1}, {1, 1}, {10, 
   10}, {10, -10}, {1, -1}, {-1, -1}, {-10, -10}, {-10, 10}, {-1, 1}},
  PlotStyle -> Directive[Red, Dashed, Thickness[0.008]], 
 Filling -> {1 -> Axis}, FillingStyle -> White, 
 Background -> Lighter[Gray, 0.85]]

Answer 4

coords = {{-1, 1}, {1, 1}, {10, 10}, {10, -10}, {1, -1}, {-1, -1}, 
  {-10, -10}, {-10, 10}, {-1, 1}};

Graphics[{Lighter[Gray, 0.5], Rectangle @@ (Scaled /@ {{0, 0}, {1, 1}}), 
    EdgeForm[{Red, Dashed, AbsoluteThickness[3]}], White, Polygon @ coords}, 
  AspectRatio -> 1/GoldenRatio, Axes -> True]

Graphics[{Directive[Red, Dashed, AbsoluteThickness[4]], Line @ coords, 
  Lighter[Gray, 0.5], FilledCurve[Line /@ 
    {Scaled /@ {{0, 0}, {0, 1}, {1, 1}, {1, 0}, {0, 0}}, coords}]}, 
 AspectRatio -> 1/GoldenRatio, Axes -> True]

Answer 5

The even-odd rule for FilledCurve can be used:

Module[{shape = {Line[{{-1, 1}, {1, 1}, {10, 10}, {10, -10}, {1, -1},
       {-1, -1}, {-10, -10}, {-10, 10}, {-1, 1}}]},
  universe = {Line[{{-100, 100}, {100, 100}, {100, -100}, {-100, -100},
       {-100, 100}}]}, 
  bounds = {{-10.5, 10.5}, {-11, 11}}}, 
 Graphics[{Lighter[Gray, .75], FilledCurve[{shape, universe}], Dashed,
    Red, Thickness[.008], JoinedCurve[shape]}, 
  AspectRatio -> (1/GoldenRatio), Axes -> True, PlotRange -> bounds, 
  ImageSize -> 360]]