Hide mesh in some parts of Plot3D

Question

Is it possible to hide part of the mesh in a Plot3D plot? For example, in the plot

Plot3D[x + y, {x, 0, 4}, {y, 0, 4}, Mesh -> {{1, 2, 3}, {1, 2, 3}}]

could I hide the mesh for x<2 and y<2?

My goal is to show a specific mesh in a Plot3D without modifying the internal mesh used for plotting, as this would be too expensive to get the desired mesh. The grid I want displayed is roughly structured, so I could plot it in the way above and just remove those parts of the lines I do not want.

Answer 1

You may use the MeshFunctions option of Plot3D with ImplictRegion.

With region in OP

r = ImplicitRegion[x < 2 && y < 2, {x, y}];

then

Plot3D[x + y, {x, 0, 4}, {y, 0, 4}
 , Mesh -> {{1, 2, 3}, {1, 2, 3}}
 , MeshFunctions -> {
   If[{#1, #2} ∈ r, 0, #1] &
   , If[{#1, #2} ∈ r, 0, #2] &
   }
 ]

You can use any region. However, for some you may have to increase the PlotPoints to get the mesh to connect nicely.

For example,

r2 = ImplicitRegion[(x - 2)^2 + (y - 2)^2 <= 1, {x, y}];

Plot3D[x + y, {x, 0, 4}, {y, 0, 4}
 , Mesh -> 5
 , MeshFunctions -> {
   If[{#1, #2} ∈ r2, 0, #1] &
   , If[{#1, #2} ∈ r2, 0, #2] &
   }
 , PlotPoints -> 100
 ]

Easy to Manipluate as well.

Manipulate[
 region = 
  ImplicitRegion[(x - First@c)^2 + (y - Last@c)^2 <= 1, {x, y}];
 Plot3D[x + y, {x, 0, 4}, {y, 0, 4}
  , Mesh -> 5
  , MeshFunctions -> {
    If[{#1, #2} ∈ region, 0, #1] &
    , If[{#1, #2} ∈ region, 0, #2] &
    }
  , PlotPoints -> ControlActive[20, 100]
  ]
 , {{c, {2, 2}, "Center"}, {0, 0}, {4, 4}, {.01, .01}, 
  Appearance -> "Labeled"}
 , {region, None}
 ]

Hope this helps.

Answer 2

Show[
 Plot3D[x + y, {x, 0, 2}, {y, 0, 2},
  Mesh -> None],
 Plot3D[ConditionalExpression[x + y, x >= 2 || y >= 2], 
  {x, 0, 4}, {y, 0, 4},
  Mesh -> {{1, 2, 3}, {1, 2, 3}}],
 PlotRange -> All]