Using Piecewise to create a periodic waveform

Question

I want to create a piecewise function that repeats after t=T.

Clear[t, T, s];
T = 5;
s[t_] := \[Piecewise] {
   {t, 0 < t <= 1},
   {1, 1 < t <= 2},
   {-t + 3, 2 < t <= 3},
   {0, 3 < t <= T}
  }

To make it periodic, I add the following:

s[t_] := s[t - T] /; t > T
Plot[{s[t], Evaluate@D[s[t], t]}, {t, 0, 12}, Exclusions -> None]

It plots alright, but the derivative of s[t] stops at the end of T.

Question What is the correct way of defining and plotting the derivative and integral of a periodic waveform defined using the Piecewise function?

Thanks in advance for your help and suggestions.

Answer 1

One way could be

Clear[t, T, s, s0];
T = 5;
s[t_] := Piecewise[{{s0[Mod[t, T]], t > T}, {s0[t], True}}]
s0[t_] := Piecewise[{{t, 0 < t <= 1}, {1, 1 < t <= 2}, {-t + 3, 
    2 < t <= 3}, {0, 3 < t <= T}}]

and now

Plot[s[t], {t, 0, 12}, Exclusions -> None]

and

Plot[Evaluate[D[s[t], t]], {t, 0, 12}, Exclusions -> None]

And

Plot[{s[t], Evaluate[D[s[t], t]]}, {t, 0, 12}, Exclusions -> None]

Answer 2

Clear[s];

s[t_?(0<=#<=5&)]:=\[Piecewise]{
  {t,0<=t<=1},
  {1,1<t<=2},
  {-t+3,2<t<=3},
  {0,3<t<=5}
};

s[t_?(Element[#,Reals]&)]:=s[Mod[t,5]];

---

Edit by @Syed (to include plot)

Plot[{s[t], Evaluate[D[s[t], t]]}, {t, 0, 12}, Exclusions -> None]

**** Edit **** The derivative plotted above has errors.

Wolfram Tech Support said: Since there are conditions on the input, there is no symbolic derivative, so s'[real number] is computing an approximate derivative, which is of very low quality.

Another solution is given above that works much better.