Indicating the probability that a weather datum is above/below some given value on a geographic map

Question

With help of the previous questions here, I am analyzing weather data as daily MeanWindSpeed of some cities with the following code:

  {date, year, month, day, wind} = {1, 1, 2, 3, 2}

  cityWind1 = WeatherData["Bodo", "MeanWindSpeed", {{1973, 1, 1}, {2013, 5, 1},"Day"}];
  cityWind1[[All, date, year]] = 0

  slowWinddays1 = Select[cityWind1, #[[wind]] < 21 &];
  DateListPlot[{cityWind1, slowWinddays1}, ImageSize -> 600]

I have two problems.

1. I want to calculate the probability of the days that mean wind speeds higher than 21 km/hr and show it in the plot. It could be monthly or weekly outlet. I know the algorithm is too easy, but sorry guys I am new in town!

2. Most important, how can I show this probability in different geographic regions based on data from the available stations of that region. For example, assign a color to Norway and vary intensity to indicate the probability on the geographic map. That is to say, the more intense the color, the higher the probability.

Answer 1

A hint for the mapping thing:

d = {2013, 5, 1}; 
cords = Select[Reverse[CityData[#, "Coordinates"]] & /@ CityData[{All, "Norway"}], Head@# == List &];
Show[ListContourPlot[Join@@ {#,List@WeatherData[#,"MeanWindSpeed",d,d,"Day"}][[1, 2]]} & /@ cords], 
     Graphics[{Gray, Opacity[.5], CountryData["Norway", "Polygon"]}]]

Answer 2

Here's a quick answer for your first question (I'll let someone else handle the mapping (that's a lot of data to sort through).

Let's look at the wonderful (cough) city of Houston.

winddata = WeatherData[{"Houston", "Texas"}, "MeanWindSpeed", 
   {{1973, 1, 1}, {2013, 5, 1}, "Day"}];

Gather those values by day:

daysorted = GatherBy[winddata, #[[1, {2, 3}]] &];

Calculate the probability of each of those days exceeding a certain wind speed:

windspeed = 10;    
probs = Most[Probability[x >= windspeed, x \[Distributed] #[[All, 2]]]& /@  daysorted];
dates = Most@daysorted[[All, 1, 1]];
plotprobs = Transpose[{dates, probs}]; (*prepare for plotting*)

Plot away:

winddata[[All, 1, 1]] = 0;
slowWinddays1 = Select[winddata, #[[2]] < windspeed &];
plot1 = DateListPlot[plotprobs, Joined -> True, ImageSize -> 600];
plot2 = DateListPlot[{winddata, slowWinddays1}, ImageSize -> 600];
Column[{plot2,plot1}]

Aside: Yes, you don't have to use Probability, but why not?