2
$\begingroup$

I've tried NSolve, Solve and Reduce for solving this equation but non of them worked. would you please help me?

NSolve[Log[Sqrt[x]/(1 + Sqrt[x])] == 3 Sqrt[1 - x], x]
NSolve::nsmet: This system cannot be solved with the methods available to NSolve.
$\endgroup$
3
  • 1
    $\begingroup$ The closest your left-hand-side ever gets to your right-hand-side is for $x=1$; but there is no actual solution for $x\in\mathbb{C}$. $\endgroup$
    – Roman
    Nov 27 '21 at 11:29
  • $\begingroup$ There does not seem to be solution in the reals. Solve[Log[Sqrt[x]/(1 + Sqrt[x])] - 3 Sqrt[1 - x] == 0 && -100 <= x <= 100, x, Reals] gives {} $\endgroup$
    – Nasser
    Nov 27 '21 at 11:56
  • $\begingroup$ Looks ill-posed: there would be a real solution if another branch of square root were chosen on the right side and maybe others if other branches on the left are chosen as well. $\endgroup$
    – josh
    Nov 27 '21 at 12:09
6
$\begingroup$

Divide by "Sqrt[1-x]" and define the function:

f[x_] = 1/Sqrt[1 - x] Log[Sqrt[x]/(1 + Sqrt[x])]

Now check the behavior of this function. It will be concentrated around 0 and 1. Note the phase as indicated by the legend:

ComplexPlot3D[f[x], {x, -3 - 3 I, 3 + 3 I}, PlotRange -> {0, 4}, 
 PlotLegends -> Automatic]

enter image description here

You see that the function comes nowhere near +3. It would be red and have a magnitude of 3. Therefore, your equation has no solution in the complex numbers.

$\endgroup$
0
$\begingroup$

You can try fixed point iteration:

(* First find a suitable rearrangement by replacing an x with c and solve *)
eqn = Log[Sqrt[x]/(1 + Sqrt[x])] == 3 Sqrt[1 - c];

(* 1/9 (9 - Log[Sqrt[x]/(1 + Sqrt[x])]^2) *)

(* Now find a fixed point if one exists *)
FixedPoint[1 - (Log[Sqrt[#]/(1 + Sqrt[#])]/3)^2 &, 1.0, 50]

(* 0.9443735327111197` *)

(* Try it out on both sides: *)
Log[Sqrt[0.9443735327111197`]/(1 + Sqrt[0.9443735327111197`])]
(* -0.707558 *)

3 Sqrt[1 - 0.9443735327111197`]
(* 0.707558 *)

So as you can see, @josh 's comment about the branches is right, as the Sqrt on the right hand side is using the negative square root. This agrees with FindInstance if you square both sides:

x /. First@FindInstance[9 (1 - x) == Log[1 - 1/(1 + Sqrt[x])]^2, x]
(* Root[{9 - Log[1 - (1 + #^Rational[1, 2])^(-1)]^2 - 9 #& , 
  0.9443735327111196808405153254286572521300613203544128514706`30.15051499783199}] *)
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.