What does the function Internal`InheritedBlock do? How is it different from the regular Block?
$\begingroup$
$\endgroup$
1
-
4$\begingroup$ Popular use of this function started with Daniel's MathGroup post: forums.wolfram.com/mathgroup/archive/2010/Dec/msg00710.html $\endgroup$– Mr.WizardMay 25, 2013 at 15:21
Add a comment
|
1 Answer
$\begingroup$
$\endgroup$
0
Internal`InheritedBlock (IIB) is similar to Block, except that it preserves the original definition of the function being passed to it. The function can then be modified as we wish inside the IIB without affecting the external definition.
Let's see how Block works first:
f[x_] := x
Block[{f},
Print@DownValues[f];
f[x_, y_] := x y;
Print@DownValues[f];
];
Print@DownValues[f];
(* {} *)
(* {HoldPattern[f[x_, y_]] :> x y} *)
(* {HoldPattern[f[x_]] :> x} *)
You notice that the original definition of f is not available inside the Block. On the other hand, look at what IIB does:
f[x_] := x
Internal`InheritedBlock[{f},
Print@DownValues[f];
f[x_, y_] := x y;
Print@DownValues[f];
];
Print@DownValues[f];
(* {HoldPattern[f[x_]] :> x} *)
(* {HoldPattern[f[x_]] :> x, HoldPattern[f[x_,y_]] :> x y} *)
(* {HoldPattern[f[x_]] :> x} *)
The original definition of f is available inside its scope, and new definitions are added to the existing ones (as is the usual behaviour), unless you explicitly clear them.
