Euler-method implementation

Question

How can I implement this pseudocode in Mathematica?

Algorithm:

(* input: f, x0, xmax, y0, n  *)

h = (xmax-x0)/n;
u[1] = x0;
v[1] = y0;
For i = 2,n+1:
    u[i] = u[i-1] + h;
    v[i] = v[i-1] + h * f( u[i-1] , v[i-1] );
End for.
Return {{u[1],v[1]},{u[2],v[2]},...,{u[n+1],v[n+1]}};

This is my take on it but it's not working properly.

MyEuler[f, x0, xmax, y0, n] = Module[{},
  h = (xmax - x0)/n;
  u[1] = x0;
  v[1] = y0;
  For[i = 2, i <= n + 2, i++,
    u[i] = u[i - 1] + h;
    v[i] = v[i - 1] + h*f (u[i - 1], v[i - 1]);]
   Table[{u[k], v[k]}, {k, 1, n + 1}]]

Answer 1

There are several syntactical mistakes in your code.

1. Function arguments are missing an underscore:

MyEuler[f_, x0_, xmax_, y0_, n_]

2. You should use SetDelayed instead of Set, that is: you are missing a colon:

MyEuler[f_, x0_, xmax_, y0_, n_] :=

3. Calling a function requires square brackets, not round ones:

f[u[i - 1], v[i - 1]]

4. Separate For from Table by the additional semicolon:

For[ ... ]; Table[ ... ]

Put all of this together, and the code should work:

MyEuler[f_, x0_, xmax_, y0_, n_] := Module[{},
  h = (xmax - x0)/n;
  u[1] = x0;
  v[1] = y0;
  For[i = 2, i <= n + 2, i++,
   u[i] = u[i - 1] + h;
   v[i] = v[i - 1] + h*f[u[i - 1], v[i - 1]]
   ];
  Table[{u[k], v[k]}, {k, 1, n + 1}]
  ]

f[x_, y_] := x + y;

MyEuler[f, 0, 1, 0, 3]

(* {{0, 0}, {1/3, 0}, {2/3, 1/9}, {1, 10/27}} *)

Answer 2

In a functional style, I recommend NestList, the key trick of which is to properly define an iteration function to be used repeatedly via pure/anonymous Function (&). And more can be found out in @MichaelE2 's comments.

Clear[myEuler]
myEuler[f : (_Symbol | _Function), x0_Real, xmax_Real, y0_Real, n_Integer] :=
Module[{h = (xmax - x0)/n, iterate},
    iterate = # + h {1, f @@ #} &;
    NestList[iterate, {x0, y0}, n]
]

Note that, considering the numeric nature of the problem, here I set explicitly type checking for each argument of myEuler. The consequence is that unless all the type checking returns True, myEuler will refuse to run. In this way would it be disentangled with MMA's symbolic ability to some extend, which is actually not needed here.

As an example, I set $ f(x, y) = x^2 + y^2, x_0 = 0., x_\text{max} = 1., y_0 = .1 $, and $ n = 100 $, and get the result plotted as below: