How can I make this rectangle in GeoGraphics look like a rectangle?

Question

I evaluated this.

{lon1, lat1} = {-76.4408, 38.0825};
{lon2, lat2} = {-76.5054, 38.1413};
{lon3, lat3} = {-76.3546, 38.2446};
{lon4, lat4} = {-76.2900, 38.18582};
dir12 = GeoDirection[{lat1, lon1}, {lat2, lon2}];
dir23 = GeoDirection[{lat2, lon2}, {lat3, lon3}];
dir34 = GeoDirection[{lat3, lon3}, {lat4, lon4}];
dir41 = GeoDirection[{lat4, lon4}, {lat1, lon1}];
{dir12 - dir41,
  dir41 - dir34 + Quantity[360, "AngularDegrees"],
  dir23 - dir12,
  dir34 - dir23
}

So each corner is approximately 90 degrees. However, below it looks like the corners at the top and bottom are about 98 degrees and the corners on the left and right look to be about 82 degrees.

GeoGraphics[{
   Polygon[{{lon1,lat1},{lon2,lat2},{lon3,lat3},{lon4,lat4}}]},
   GeoRange->{{38.073,38.255},{-76.515,-76.28}}
]

I have macOS v10.15.7 (Catalina) and...

$Version
12.0.0 for Mac OS X x86 (64-bit) (April 7, 2019)

How can I make the rectangle in this GeoGraphics look like a rectangle?

Answer 1

Mathematica is defaulting to a non-conformal projection. (A "conformal" projection is one for which angles on the map are equal to angles on the Earth's surface.) The reason, and the solution, are buried deep in the GeoProjection documentation:

When one or more non-geographic primitives appear and no projection is explicitly requested, the equirectangular projection is always used. [The equirectangular projection is non-conformal—ed.] Use GeoDisk, Line[{GeoPosition[…], …}], etc. to place correctly projected primitives on the map:

GeoGraphics[Polygon[
   {GeoPosition[{lat1, lon1}], GeoPosition[{lat2, lon2}], 
    GeoPosition[{lat3, lon3}], GeoPosition[{lat4, lon4}]}]]

I should note that trying to explicitly specify the projection using the option GeoProjection -> "LambertAzimuthal" or the like does not seem to work.¹

Finally, note that v12.2 includes GeoPolygon, use of which makes the above code a bit less cumbersome.

---

¹ Note to pedants: Yes, I know that the Lambert azimuthal projection isn't conformal either, but it's pretty darn close at the center of the projection, and this map is small enough that it doesn't really matter.

Answer 2

A more concise version of what Michael Seifert provided works.

GeoGraphics[Polygon[GeoPosition@{
  {{lat1,lon1},{lat2,lon2},{lat3,lon3},{lat4,lon4}}
}]]