0
$\begingroup$

enter image description here

I want to place this slider below the x-axis and Vertically beside the y-axis.

$\endgroup$
2

3 Answers 3

3
$\begingroup$

One approach:

Manipulate[
 Manipulate[Plot[Sin[x (1 + x)], {x, 0, 6}],
  {a, 0, 2},
  ControlPlacement -> Bottom,
  Paneled -> False],
 {y, 0, 6},
 ControlPlacement -> Left,
 ControlType -> VerticalSlider,
 Alignment -> Bottom,
 Paneled -> False]

enter image description here

Also, building up what you want to do from Dynamic may give you additional control over control placement.

$\endgroup$
3
$\begingroup$
Clear["Global`*"]

$Version

(* "12.3.1 for Mac OS X x86 (64-bit) (June 19, 2021)" *)

Manipulate[
 Plot[x*Sin[x], {x, xint[[1]], xint[[2]]},
  PlotRange -> {yint[[1]], yint[[2]]},
  ImageSize -> 360],
 {{xint, {0, 2 Pi}, "x interval"},
  0, 2 Pi, Pi/50.,
  ControlType -> IntervalSlider,
  Method -> "Push", MinIntervalSize -> Pi/50., Appearance -> "Labeled",
  ControlPlacement -> Bottom},
 {{yint, {-5, 2}, "y interval"},
  -5, 2, 0.05,
  ControlType -> IntervalSlider,
  Method -> "Push", MinIntervalSize -> 0.05, 
  Appearance -> {"Vertical", "Labeled"},
  ControlPlacement -> Left}]

enter image description here

$\endgroup$
0
$\begingroup$

Something like this?

Manipulate[Plot[Sin[x (1 + a x)], {x, 0, 6}], {a, 0, 2}, 
 ControlPlacement -> Bottom]

('ControlPlacement' is the thing that may help. Compare with

Manipulate[Plot[Sin[x (1 + a x)], {x, 0, 6}], {a, 0, 2}, 
 ControlPlacement -> Top]

Depends you your code.)

Looks like one of your controls wants to be a VerticalSlider.

DynamicModule[{x = 0}, 
 Row[{VerticalSlider[Dynamic[x], Appearance -> "RightArrow"], 
   Graphics[
    Table[{Hue[i], Rectangle[{0, i}, {0.1, i + 0.01}]}, {i, 0, 1, 
      0.01}], ImageSize -> {30, 200}], 
   VerticalSlider[Dynamic[x], Appearance -> "LeftArrow"], "   ", 
   Dynamic@Graphics[{Hue[x], Disk[]}]}]]
$\endgroup$

Not the answer you're looking for? Browse other questions tagged or ask your own question.