2
$\begingroup$

The result in 12.3.1 on Windows 10 of

as1 = AsymptoticIntegrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}, {x, Infinity, 1}]

-ArcSinh[2] Log[2]^2 + ArcSinh[x] Log[x]^2

(The same result is obtained with the Assumptions->x>0 option.) is not confirmed numerically in view of discordance between

as1 /. x -> 1000.0000000000000000000000000

361.9993064078083517853350815

and

NIntegrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, 1000}]

109.662

Usually AsymptoticIntegrate works as the composition of Series with Integrate. Let us try it:

Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}, Assumptions -> x > 2]

-4 HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/2}, -4] + 2 x HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/2}, -x^2] - ArcSinh[2] Log[2]^2 + HypergeometricPFQ[{1/2, 1/2, 1/2}, {3/2, 3/2}, -4] Log[16] - 2 x HypergeometricPFQ[{1/2, 1/2, 1/2}, {3/2, 3/2}, -x^2] Log[x] + ArcSinh[x] Log[x]^2

Series[%, {x, Infinity, 2}]

$\frac{1}{24} \left(-96 \, _4F_3\left(\frac{1}{2},\frac{1}{2},\frac{1}{2},\frac{1}{2};\frac{3}{2},\frac{3}{2},\frac{3}{2};-4\right)+24 \log (16) \, _3F_2\left(\frac{1}{2},\frac{1}{2},\frac{1}{2};\frac{3}{2},\frac{3}{2};-4\right)+8 \log ^3(x)+12 \log (4) \log ^2(x)+12 \gamma \log ^2(x)+12 \psi ^{(0)}\left(\frac{1}{2}\right) \log ^2(x)-\gamma ^3-2 \gamma \pi ^2-\psi ^{(0)}\left(\frac{1}{2}\right)^3-3 \gamma \psi ^{(0)}\left(\frac{1}{2}\right)^2-3 \gamma ^2 \psi ^{(0)}\left(\frac{1}{2}\right)-2 \pi ^2 \psi ^{(0)}\left(\frac{1}{2}\right)-\psi ^{(2)}\left(\frac{1}{2}\right)+\psi ^{(2)}(1)-24 \log ^2(2) \sinh ^{-1}(2)\right)+\frac{2 \log ^2(x)+2 \log (x)+1}{8 x^2}+O\left(\left(\frac{1}{x}\right)^3\right)$

Normal[%] /. x -> 1000.000000000000000000000000

109.6620820304208683244267272

It looks like a happy end. However, there is a simple elementary asymptotic Log[x]^3/3 which can be verified by

Limit[D[Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}], x]/D[Log[x]^3/3, x], x -> Infinity]

1

Can a more exact elementary asymptotic be derived with Mathematica?

$\endgroup$
3
  • $\begingroup$ It should be noticed that as2 = AsymptoticIntegrate[ Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}, {x, Infinity, 2}] returns the input. $\endgroup$
    – user64494
    Oct 5, 2021 at 14:50
  • $\begingroup$ Log[x]^3/3/.x->1000. results in 109.873. $\endgroup$
    – user64494
    Oct 5, 2021 at 16:14
  • $\begingroup$ Mathematica 12.2 states Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, Infinity}] doesn't converge. If 12.3 states the same, what kind of asymptotic behavior do you expect? $\endgroup$ Oct 6, 2021 at 14:33

2 Answers 2

3
$\begingroup$

It can be shown that difference between the exact integral and Log[x]^3/3 goes to the constant dlim = 0.210576 . So substract this dlim from Log[x]^3/3 to get an ideal asymptote at infinity, but not so good at low x.

int1[x_] = 
FullSimplify[
Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}, Assumptions -> x > 2], 
Assumptions -> x > 2]

(*   -4 HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/2}, -4] + 
2 x HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/2}, -x^2] - 
ArcSinh[2] Log[2]^2 + Log[2] (ArcCsch[2] + Log[2])^2 - 
ArcSinh[2]^2 Log[4] + ArcSinh[2] Log[4] Log[3 + Sqrt[5]] - 
ArcSinh[x]^2 Log[x] + ArcSinh[x] Log[x]^2 + 1/6 \[Pi]^2 Log[2 x] - 
2 ArcSinh[x] Log[x] Log[1 - x + Sqrt[1 + x^2]] - 
Log[4] PolyLog[2, 2 - Sqrt[5]] + 
Log[4] PolyLog[2, -(1/(1 + Sqrt[5]))] + 
2 Log[x] PolyLog[2, x - Sqrt[1 + x^2]] - 
2 Log[x] PolyLog[2, 1 + x - Sqrt[1 + x^2]]   *)

LogLinearPlot[{0.210576, Log[x]^3/3 - int1[x]}, {x, 2, 10^6}, 
PlotPoints -> 20, MaxRecursion -> 1, PlotStyle -> {Red, Blue}]

dlim = Limit[Log[x]^3/3 - int1[x], x -> \[Infinity]] //    FullSimplify

(*   4 HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/2}, -4] - 
1/3 \[Pi]^2 Log[2] - ArcCsch[2]^2 Log[2] - 2 ArcCsch[2] Log[2]^2 + 
ArcSinh[2] Log[2]^2 - (4 Log[2]^3)/3 + ArcSinh[2]^2 Log[4] - 
ArcSinh[2] Log[4] Log[3 + Sqrt[5]] + Log[4] PolyLog[2, 2 -  Sqrt[5]] -
Log[4] PolyLog[2, -(1/(1 + Sqrt[5]))] - Zeta[3]/2   *)

dlim // N      (*   0.210576   *)

Edit

By the way, you don't have to guess Log[x]^3/3 , you get it if you take Series of int1 at infinity and FullSimplify. Then the only term dependend on x is this Log-term and the constant is dlim.

ser4 = Series[int1[x], {x, \[Infinity], 0}] // Normal // 
 FullSimplify[#, x > 2] &

(*   1/6 (-24 HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2},  {3/2, 3/2, 3/
  2}, -4] + 8 Log[2]^3 + \[Pi]^2 Log[4] + 
Log[64] (ArcCsch[2] (ArcCsch[2] + Log[4]) + 
  ArcSinh[2] Log[3 - Sqrt[5]]) 
+ 2 Log[x]^3 
+ 12 Log[2] (-PolyLog[2, 2 - Sqrt[5]] + 
  PolyLog[2, -(1/(1 + Sqrt[5]))]) + 3 Zeta[3])   *)
$\endgroup$
1
  • $\begingroup$ Many thanks from me to you for your analysis. I am glad that Mathematica can do it. In 12.3.1 on Windows 10 ser4 is 1/24 (Log[4]^3 + \[Pi]^2 Log[16] + 8 Log[x]^3 + 12 (-8 HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/ 2}, -4] - 2 ArcSinh[2] Log[2]^2 + HypergeometricPFQ[{1/2, 1/2, 1/2}, {3/2, 3/2}, -4] Log[256] + Zeta[3])). $\endgroup$
    – user64494
    Oct 6, 2021 at 5:46
1
$\begingroup$

Sorry I'm a little bit late:

From the definition f[x] == Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}] it follows

f[2]==0 
f'[x]==Log[x]^2/Sqrt[x^2 + 1] 

which is solved directly

F = Values@DSolve[{f'[x] == Log[x]^2/Sqrt[x^2 + 1], f[2] == 0}, f, x][[1, 1]]
(*Function[{x}, -4 HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/
 2}, -4] +  2 x HypergeometricPFQ[{1/2, 1/2, 1/2, 1/2}, {3/2, 3/2, 3/
 2}, -x^2] + 4 HypergeometricPFQ[{1/2, 1/2, 1/2}, {3/2, 3/2}, -4] Log[2] -ArcSinh[2] Log[2]^2 - 2 x HypergeometricPFQ[{1/2, 1/2, 1/2}, {3/2, 3/2}, -x^2] Log[x] +ArcSinh[x] Log[x]^2]*)

Asymptotically we get a Series in Log[x]

Series[F[x], {x, Infinity, 1}]
(*-0.210576 + 0.333333 Log[x]^3+O[1/x]^2*)
$\endgroup$
8
  • $\begingroup$ Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}, Assumptions -> x > 2] produces the same as your F (see the question, line 12). $\endgroup$
    – user64494
    Oct 6, 2021 at 16:53
  • $\begingroup$ Also Series[F[x], {x, Infinity, 1}] produces a part of the expression in lines 19-22 of the question. $\endgroup$
    – user64494
    Oct 6, 2021 at 16:59
  • $\begingroup$ @user64494 My answer shows another way to solve the problem, though it's not surprising to get the same answers! $\endgroup$ Oct 6, 2021 at 20:38
  • $\begingroup$ It's trivial that DSolve[{f'[x] == Log[x]^2/Sqrt[x^2 + 1], f[2] == 0}, f, x] is equivalent to Integrate[Log[t]^2/Sqrt[t^2 + 1], {t, 2, x}, Assumptions -> x > 2], isn't it? $\endgroup$
    – user64494
    Oct 8, 2021 at 8:40
  • $\begingroup$ Sure it is trivial, if you know th Fundamental theorem of calculus. But my answer shows a way to solve your problem with Mathamatica version <12.3! $\endgroup$ Oct 9, 2021 at 10:18

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.