How to impose golden color on 3D object with flat surface?

Question

I would like to have a 3D object with a golden color as in the attached image, how can I create such color and edges in Mathematica?

Here is my try

    Graphics3D[{Specularity[Gray, 1], EdgeForm[None], Orange, 
  Lighting -> "Neutral", Opacity[0.95], 
  Cuboid[{0, 0, 0}, {6, 1.2, 1.3}]}, Boxed -> False, 
 ViewPoint -> {2, 0.2, 1}, PlotRange -> {{-2, 6}, {-2, 2}, {-2, 2}}]

Answer 1

We can add custom settings to MaterialShading, use non default Lighting, and add a rounding radius to our block. The various settings in MaterialShading can be changed to give different effects:

massoc = 
  Association[{"BaseColor" -> RGBColor[1., 0.75, 0., 1.], 
    "SpecularColor" -> GrayLevel[1], "MetallicCoefficient" -> 0.8, 
    "RoughnessCoefficient" -> 0.5, "AmbientExposureFraction" -> 1., 
    "SpecularAnisotropyCoefficient" -> 0.3}];

r = 0.05;
{c1x, c1y, c1z} = {0, 0, 0} + r;
{c2x, c2y, c2z} = {6, 1.2, 1.3} - r;
faces = Polygon[{
    {{c1x, c1y - r, c1z}, {c2x, c1y - r, c1z}, {c2x, c1y - r, c2z}, {c1x, c1y - r, c2z}},
    {{c1x, c2y + r, c1z}, {c2x, c2y + r, c1z}, {c2x, c2y + r, c2z}, {c1x, c2y + r, c2z}},
    {{c1x, c1y, c2z + r}, {c2x, c1y, c2z + r}, {c2x, c2y, c2z + r}, {c1x, c2y, c2z + r}},
    {{c1x, c1y, c1z - r}, {c2x, c1y, c1z - r}, {c2x, c2y, c1z - r}, {c1x, c2y, c1z - r}},
    {{c1x - r, c1y, c1z}, {c1x - r, c2y, c1z}, {c1x - r, c2y, c2z}, {c1x - r, c1y, c2z}},
    {{c2x + r, c1y, c1z}, {c2x + r, c2y, c1z}, {c2x + r, c2y, c2z}, {c2x + r, c1y, c2z}}
    }];
tubes = Tube[{
    {{c1x, c1y, c1z}, {c2x, c1y, c1z}}, {{c1x, c1y, c1z}, {c1x, c2y, c1z}}, {{c1x, c1y, c1z}, {c1x, c1y, c2z}},
    {{c2x, c2y, c2z}, {c1x, c2y, c2z}}, {{c2x, c2y, c2z}, {c2x, c1y, c2z}}, {{c2x, c2y, c2z}, {c2x, c2y, c1z}},
    {{c1x, c2y, c1z}, {c2x, c2y, c1z}}, {{c2x, c1y, c1z}, {c2x, c2y, c1z}}, {{c2x, c1y, c1z}, {c2x, c1y, c2z}},
    {{c1x, c1y, c2z}, {c2x, c1y, c2z}}, {{c1x, c2y, c2z}, {c1x, c2y, c1z}}, {{c1x, c2y, c2z}, {c1x, c1y, c2z}}
    }, r];

Graphics3D[
 {MaterialShading[massoc], faces, tubes},
 Boxed -> False,
 Lighting -> "ThreePoint",
 ViewPoint -> {2, 0.2, 1},
 ViewVertical -> {0, 0, 1}
]

Answer 2

Needs["OpenCascadeLink`"];
shape = OpenCascadeShape[Cuboid[{0, 0, 0}, {3, 1, 1}]];
fillet = OpenCascadeShapeFillet[shape, 0.04];
bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[fillet];
Show[bmesh[
  "Wireframe"[
   "MeshElementStyle" -> 
    Directive[EdgeForm[], 
     FaceForm[MaterialShading[{"Gold", Darker@Yellow}]]]]], 
 Lighting -> "Standard"]

Edit

Test another solids.

Clear["`*"];
Needs["OpenCascadeLink`"];
bmesh[solid_, l_ : .05] := Module[{shape, fillet, bm},
   shape = OpenCascadeShape[solid];
   fillet = OpenCascadeShapeFillet[shape, l];
   bm = OpenCascadeShapeSurfaceMeshToBoundaryMesh[fillet];
   Show[bm[
     "Wireframe"[
      "MeshElementStyle" -> 
       Directive[EdgeForm[], 
        FaceForm[MaterialShading[{"Gold", Darker@Yellow}]]]]], 
    Lighting -> "Standard"]
   ];
solid1 = PolyhedronData["Cube", "Polyhedron"];
solid2 = PolyhedronData["Dodecahedron", "Polyhedron"];
solid3 = TruncatedPolyhedron[Icosahedron[], 1/3];
solid4 = AugmentedPolyhedron[Dodecahedron[]];
bmesh[solid2, .05]

Answer 3

From version 12.3 on, there is a new graphics directive called MaterialShading for various materials.

Graphics3D[{MaterialShading["Gold"], 
  Cuboid[{0, 0, 0}, {6, 1.2, 1.3}]}, Boxed -> False]

However, you will probably have to play around with different lighting settings to achieve a similar result as in the photo.