1
$\begingroup$

The solution of fun[x,y]>0 leads to the following output

 fun[x_, y_] = (1/16)*(1 - 6*x*y + (-1 + x)*x*y)*(1 + x*(-1 + 6*y) + 
     x*(-1 + x + y - x*y))*(-1 + 2*x - 
     x^2 + (x + (-1 + x)*x*(-1 + y) - 6*x*y)*(6*x*y + (x - x^2)*y)); 
Reduce[fun[x, y] > 0 && 0 < x < 1 && 0 < y < 1, y]

$$\color{blue}{\left(\frac{1}{2} \left(7-3 \sqrt{5}\right)<x\leq 2-\sqrt{2}\land -\frac{1}{x^2-7 x}<y<1\right) }\lor \color{red}{ \left(2-\sqrt{2}<x<1 \land \left(\frac{x-2}{2 (x-7)}-\frac{1}{2} \sqrt{\frac{x^4-4 x^3+8 x-4}{(x-7)^2 x^2}}<y<\frac{1}{2} \sqrt{\frac{x^4-4 x^3+8 x-4}{(x-7)^2 x^2}}+\frac{x-2}{2 (x-7)}\lor -\frac{1}{x^2-7 x}<y<1\right)\right)}$$

The way I understand this is:

  1. blue and red are two solutions
  2. when $x$ lies in range $\frac{1}{2} \left(7-3 \sqrt{5}\right)<x\leq 2-\sqrt{2}$, $y$ can take values in the range $\color{green}{-\frac{1}{x^2-7 x}<y<1}$
  3. when $x$ lies in range $2-\sqrt{2}<x<1$, $y$ can take values in the range $\frac{x-2}{2 (x-7)}-\frac{1}{2} \sqrt{\frac{x^4-4 x^3+8 x-4}{(x-7)^2 x^2}}<y<\frac{1}{2} \sqrt{\frac{x^4-4 x^3+8 x-4}{(x-7)^2 x^2}}+\frac{x-2}{2 (x-7)}$ $\textbf{or}$ $\color{green}{-\frac{1}{x^2-7 x}<y<1}$

Is Mathematica telling me that $y$ exists in range $-\frac{1}{x^2-7 x}<y<1$ for two different ranges of $x$?

Doesn't 2 and 3 imply $-\frac{1}{x^2-7 x}<y<1$ for $\frac{1}{2} \left(7-3 \sqrt{5}\right)<x\leq1$?

$\endgroup$
1
  • $\begingroup$ Your interpretation seems correct to me. You could plot the solution to visualize it. $\endgroup$
    – bbgodfrey
    Sep 30 at 12:42
1
$\begingroup$

In Make Reduce produce nicer output @chuy presented a comand line to make a nice looking output ot results of Reduce . I here give the form that also worked in version 8.0.

fun[x_, y_] = (1/16)*(1 - 6*x*y + (-1 + x)*x*y)*(1 + x*(-1 + 6*y) + 
 x*(-1 + x + y - x*y))*(-1 + 2*x - 
 x^2 + (x + (-1 + x)*x*(-1 + y) - 6*x*y)*(6*x*y + (x - x^2)*y));

red = Reduce[fun[x, y] > 0 && 0 < x < 1 && 0 < y < 1, y];

TraditionalForm[
red //. Or -> 
Composition[(Column[#, Right, Background -> {{White, LightGray}}, 
   Frame -> All] &), List]]

enter image description here

TraditionalForm[
 N[red] //. 
 Or -> Composition[(Column[#, Right, 
   Background -> {{White, LightGray}}, Frame -> All] &), List]]

enter image description here

$\endgroup$
0
$\begingroup$

How about

FullSimplify[(1/2 (7 - 3 Sqrt[5]) < x <= 
 2 - Sqrt[2] && -(1/(-7 x + x^2)) < y < 1) || (2 - Sqrt[2] < x < 
 1 && ((-2 + x)/(2 (-7 + x)) - 
 1/2 Sqrt[(-4 + 8 x - 4 x^3 + x^4)/((-7 + x)^2 x^2)] < 
 y < (-2 + x)/(2 (-7 + x)) + 
 1/2 Sqrt[(-4 + 8 x - 4 x^3 + 
         x^4)/((-7 + x)^2 x^2)] || -(1/(-7 x + x^2)) < y < 1)), 
 Assumptions -> 0 < x < 1 && 0 < y < 1]

1 + (-7 + x) x y < 0 || (-2 + x + Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/( 2 (-7 + x)) < y < (-2 + x - Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/( 2 (-7 + x))

? Addition.

RegionPlot[1 + (-7 + x) x y < 0 || (-2 + x + Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/
(2 (-7 + x)) < y < (-2 + x - Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/(2 (-7 + x)), 
{x, 0, 1}, {y, 0, 1}, PlotPoints -> 50]

enter image description here

RegionPlot[1 + (-7 + x) x y < 0, {x, 0, 1}, {y, 0, 1},PlotPoints -> 50]

enter image description here

RegionPlot[(-2 + x + Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/(2 (-7 + x)) < y < (-2 + x - Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/(2 (-7 + x)), {x, 0, 1}, {y, 0, 1}, PlotPoints -> 50]

enter image description here

$\endgroup$
1
  • $\begingroup$ It should be noticed that RegionPlot[1 + (-7 + x) x y < 0 || (-2 + x + Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/ (2 (-7 + x)) < y < (-2 + x - Sqrt[-4 + 8 x - 4 x^3 + x^4]/x)/(2 (-7 + x)), {x, 0, 1}, {y, 0, 1}, PlotPoints -> 400] shows this is the union of the two nonoverlapping domains. $\endgroup$
    – user64494
    Sep 30 at 15:05

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.