2
$\begingroup$

I am unable to find the limit of the following sum as t appraoches infinity

Clear["Global`*"]
S[t_] := S[
   t] = (1/(t - 1)) Sum[
    Sum[Abs[(t)/((t - 1) n (n + 1)) - 1/(t - 1)], {n, 1, j}], {j, 1, 
     t - 1}]

As t grows larger the computation time of the sum slows down.

How do we compute the limit?

Edit: According to the comments I tried RealAbs and computed the limit as t->Infinity

Clear["Global`*"]
S[t_] := S[
   t] = (1/(t - 1)) Sum[
    Sum[RealAbs[(t)/((t - 1) n (n + 1)) - 1/(t - 1)], {n, 1, j}], {j, 
     1, t - 1}]
N[Limit[S[t], {t -> Infinity, Assumptions -> Element[t, Reals]}]]
 

However, the computation time takes forever to compute.

$\endgroup$
2
  • $\begingroup$ If t is real, try adding it as an assumption and using RealAbs instead of Abs. $\endgroup$
    – Michael E2
    Commented Sep 28, 2021 at 15:50
  • $\begingroup$ @MichaelE2 I tried using RealAbs and Limits but my sums still takes a long time to compute. $\endgroup$
    – Arbuja
    Commented Sep 28, 2021 at 16:08

3 Answers 3

4
$\begingroup$

We can make an asymptotic approximation by hand and take its limit:

sum = (1/(t - 1)) Sum[    (* takes ~80 sec *)
    RealAbs[(t)/((t - 1) n (n + 1)) - 1/(t - 1)], {j, 1, t - 1}, {n, 
     1, j}, Assumptions -> t \[Element] Reals];

asymp = FullSimplify[sum /. Ceiling | Floor -> Identity, t > 100] /. 
    f : _PolyGamma | _HarmonicNumber :> 
     With[{res = Normal@Series[f, {t, Infinity, 3}]}, res /; True] // 
   Simplify;

Limit[asymp, t -> Infinity]
(* 3/2 *)

Numerical evidence for the validity of the approximation. I'll let someone else prove it rigorously.

TableForm[
 Table[Style[sum - asymp, PrintPrecision -> 16] // AbsoluteTiming, {t,
    10.`32^Range@10}],
 TableHeadings -> {Automatic, {"Timing", "Sum"}}
 ]
$\endgroup$
2
$\begingroup$

Continuation of the fine answer of @MichaelE2

sum = (1/(t - 1)) Sum[
Abs[(t)/((t - 1) n (n + 1)) - 1/(t - 1)], {j, 1, t - 1}, {n, 1, 
 j}, Assumptions -> t \[Element] Reals] // Simplify[#, t > 2] &

(*   (-4 (-1 + t) Floor[1/2 (-1 + Sqrt[1 + 4 t])]^2 + 
2 Floor[1/2 (-1 + Sqrt[1 + 4 t])]^3 + 
t (1 - 2 EulerGamma + t - 
  2 PolyGamma[0, 2 + Floor[1/2 (-1 + Sqrt[1 + 4 t])]]) + 
Floor[1/2 (-1 + Sqrt[1 + 4 t])] (2 - 3 t - 2 EulerGamma t + 
  3 t^2 - 2 t PolyGamma[0, 
    2 + Floor[1/2 (-1 + Sqrt[1 + 4 t])]]))/(2 (-1 + t)^2 (1 + 
 Floor[1/2 (-1 + Sqrt[1 + 4 t])]))   *)

The argument of all Floor is the same and it goes to infinity as t goes to infinity. It is sufficient to regard only cases where this is an integer and therefore Floor->Identity.

solt = First@Solve[1/2 (-1 + Sqrt[1 + 4 t]) == k, t, Integers] // 
   Simplify[#, {t \[Element] Integers, k \[Element] Integers, k > 2}] &

(*   {t -> k (1 + k)}   *)

sum2 = sum /. solt // Simplify[#, k \[Element] Integers && k > 2] &

(*   (k (1 + k) (3 - 2 EulerGamma - 3 k + 3 k^2 - 
     2 PolyGamma[0, 2 + k]))/(2 (-1 + k + k^2)^2)   *)

Limit[sum2, k -> \[Infinity]]

(*   3/2   *)
$\endgroup$
0
$\begingroup$

Do both divisions by (t-1) belong in the expression? If not, it must diverge. To see that, lay out the terms for any t as a lower triangular matrix. E.g.,

With[{t = 5}, PadRight@
 Table[Abs[t/(n (n + 1)) - 1]/(t - 1), {j, 1, t - 1}, {n, 1, j}]] // MatrixForm

$$ \left( \begin{array}{cccc} \frac{3}{8} & 0 & 0 & 0 \\ \frac{3}{8} & \frac{1}{24} & 0 & 0 \\ \frac{3}{8} & \frac{1}{24} & \frac{7}{48} & 0 \\ \frac{3}{8} & \frac{1}{24} & \frac{7}{48} & \frac{3}{16} \\ \end{array} \right) $$

All the entries must be positive. In any column, all the entries are the same. Now look at the first column. It's entries are all (t/2 - 1)/(t-1), which has a limit of (1/2). If the double-deflation by $(t-1)$ was intentional, then after weighting this column has a limiting sum of $1/2$, which puts a floor under the total.

$\endgroup$
2
  • 1
    $\begingroup$ Numerically, I'm getting a limit of 3/2 (up to $t=10^{12}$). $\endgroup$
    – Michael E2
    Commented Sep 28, 2021 at 16:29
  • 1
    $\begingroup$ @MichaelE2 Ah, I failed to deflate by (t-1). $\endgroup$
    – Alan
    Commented Sep 28, 2021 at 16:48

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.