I do not understand why the following equation cannot be solved in Mathematica.

Solve[Log[(-Exp[x] + Sqrt[2 - 3*Exp[2*x]])/2] == c*x, x]

The left hand side is nicely plotted in the third quadrant, and the right hand side is just a line crossing the origin. Therefore, there should be a solution for sure. However, Mathematica returns the following message.

"This system cannot be solved with the methods available to Solve"

  • 2
    $\begingroup$ "there should be a solution for sure" Yes, there exists a solution. That does not mean that Mathematica can find a closed form for this solution, or that the solution can even be expressed in closed form. IMO any "why Mathematica can't solve ..." question should come with an explanation of why you think this problem has a closed-form solution. Can you show the solution you expect? $\endgroup$
    – Szabolcs
    Sep 22, 2021 at 19:53
  • $\begingroup$ /Szablocs Maybe the better question that I should have asked in the first place is if this equation has an analytic solution. The solution will define the bound of integral that I am currently pursuing. $\endgroup$ Sep 22, 2021 at 20:14
  • $\begingroup$ A solution is optainable for discrete positive values of $c$. $\endgroup$ Sep 22, 2021 at 20:37
  • $\begingroup$ For $c=2n+1$, where $n\in \mathbb{N}$ we can define a solution as s[c_] := 1/2 Log[Root[-1 + 2 #1 + 2 #1^((1 + c)/2) + 2 #1^c &, 1]] $\endgroup$
    – yarchik
    Sep 22, 2021 at 20:46
  • $\begingroup$ Would a numerical solution (rather than an analytic one) be helpful? $\endgroup$ Sep 22, 2021 at 21:19

1 Answer 1


With substitution $z=e^x$ you get the following equation

$$\sqrt{2-3 z^2}-z=2 z^c$$

which I think is generally unsolvable in closed analytical form $z(c)$ and hence $x(c)$ for arbitrary $c$. Neither Solve (which "deals primarily with linear and polynomial equations." see details section in docs) nor Reduce can help due to principal math limitations. Then you are left with two choices:

  • Exact solutions for some integer and rational $c$
  • Numeric solution

Some integer and rational $c$


Solve[Log[1/2 (-E^x + Sqrt[2 - 3 E^(2 x)])] == x/3, x]

$x=-\frac{1}{2} \log \left(\frac{6}{7-\frac{10}{\sqrt[3]{53-3 \sqrt{201}}}-\sqrt[3]{53-3 \sqrt{201}}}\right)$


Solve[Log[1/2 (-E^x + Sqrt[2 - 3 E^(2 x)])] == 3 x, x]

$x=-\frac{1}{2} \log \left(\frac{6}{-2-\frac{4\ 2^{2/3}}{\sqrt[3]{41+3 \sqrt{201}}}+\sqrt[3]{2 \left(41+3 \sqrt{201}\right)}}\right)$

Numeric solution

You can define an inverse function

x = InverseFunction[Log[1/2 (-E^# + Sqrt[2 - 3 E^(2 #)])]/# &]

that would still yield exact solutions when it can, for instance for $c=2$:

x[2] // ToRadicals // Simplify

$\log \left(-\frac{1}{4}+\frac{1}{4 \sqrt{\frac{3}{-5-\frac{20\ 2^{2/3}}{\sqrt[3]{49+3 \sqrt{489}}}+2 \sqrt[3]{98+6 \sqrt{489}}}}}+\frac{1}{2} \sqrt{-\frac{5}{6}+\frac{5\ 2^{2/3}}{3 \sqrt[3]{49+3 \sqrt{489}}}-\frac{\sqrt[3]{49+3 \sqrt{489}}}{3\ 2^{2/3}}+\frac{3}{2} \sqrt{\frac{3}{-5-\frac{20\ 2^{2/3}}{\sqrt[3]{49+3 \sqrt{489}}}+2 \sqrt[3]{98+6 \sqrt{489}}}}}\right)$

but otherwise works numerically:

In[]:= N[x[2]]==x[2.]
Out[]= True

and even plots:

Plot[x[c], {c, 0, 7}, PlotRange -> All, PlotTheme -> "Detailed"]

enter image description here

  • $\begingroup$ Thank you for your help. $\endgroup$ Sep 28, 2021 at 11:07

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.