Different Latex is generated when changing a number from 2 to 1. Using HoldForm

Question

This is the most bizzar thing I saw with Mathematica TeXForm. Could someone please explain why it happens and if there is a workaround?

First, will show screen shot. I have an expression, when I have 2*x in it, TeXForm generates \exp for exp when using With[{...},TeXForm[HoldForm[...]]. When changing 2*x to 1*x, now e Latex is generated, same as TeXForm

This only happens when using With[{...},TeXForm[HoldForm[...]] construct. Otherwise TeXForm works same in both cases. But why?

Here is the code

ClearAll[x]

expr = 1/(Exp[(5*x - 2)/((10*x^2 - 10*x)*Exp[x] + (2*x))])
With[{z0 = expr},
  exprAsLatex = TeXForm[HoldForm[z0]];
  ];
exprAsLatex

expr = 1/(Exp[(5*x - 2)/((10*x^2 - 10*x)*Exp[x] + (1*x))])
With[{z0 = expr},
  exprAsLatex = TeXForm[HoldForm[z0]];
  ];
exprAsLatex

Using 12.3.1 on windows 10.

You might ask, why Am I using HoldForm? the reason is that this is part of larger code, where I needed to prevent evaluation of an expression while taking its Latex. The above is a MWE of the problem.

TeXForm works the same on both 2*x and 1*x :

The problem only shows up when using the With[{...},TeXForm[HoldForm[...]] method.

Answer 1

Update to give a simpler fix

As @jasonb says, TeXForm is based on TraditionalForm, and TraditionalForm checks the LeafCount of superscripts and uses exp instead of e when the LeafCount is too large. I suppose the thinking is that enormous superscripts are less readable. Unfortunately, the limit at which this switchover occurs is not configurable. The simplest fix is to wrap E in HoldForm:

expr = 1/(Exp[(5*x - 2)/((10*x^2 - 10*x)*Exp[x] + (2*x))]);
With[{z0 = expr},
    TeXForm[HoldForm[z0] /. E -> HoldForm[E]]
]

e^{-\frac{-2+5 x}{2 x+e^x \left(-10 x+10 x^2\right)}}

Another possibility is to do surgery on the TraditionalForm formatting rules, something like:

$SuperscriptLimit = 100;
Unprotect[TraditionalForm];
FormatValues[TraditionalForm] = FormatValues[TraditionalForm] /. 50 :> $SuperscriptLimit;
Protect[TraditionalForm];

Then:

expr = 1/(Exp[(5*x - 2)/((10*x^2 - 10*x)*Exp[x] + (2*x))]);
With[{z0 = expr},
    TeXForm[HoldForm[z0]]
]

e^{-\frac{-2+5 x}{2 x+e^x \left(-10 x+10 x^2\right)}}